source: trunk/configure.ac @ 1212

Last change on this file since 1212 was 1212, checked in by sam, 8 years ago

build: allow to build the Direct3D 9 driver with the mingw compiler.

File size: 11.3 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([no-define tar-ustar])
8dnl AM_MAINTAINER_MODE
9
10dnl Versioning of the separate software we ship
11LOLUNIT_VERSION=0.1
12AC_SUBST(LOLUNIT_VERSION)
13LOLREMEZ_VERSION=0.2
14AC_SUBST(LOLREMEZ_VERSION)
15
16AM_CONFIG_HEADER(config.h)
17
18AM_PROG_CC_C_O
19AC_PROG_CPP
20AC_PROG_CXX
21AC_PROG_CXXCPP
22AC_PROG_RANLIB
23
24AC_LIBTOOL_WIN32_DLL
25AM_PROG_LIBTOOL
26AC_LIBTOOL_CXX
27
28AC_C_CONST
29AC_C_INLINE
30
31dnl Ensure an error is thrown if pkg-config M4 files are not found.
32m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
33m4_pattern_forbid([^PKG_CHECK_MODULES$])
34m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
35
36dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
37if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
38  export PKG_CONFIG_LIBDIR=/dev/null
39fi
40
41dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
42dnl now otherwise it might be set in an obscure if statement. Same thing for
43dnl PKG_PROG_PKG_CONFIG which needs to be called first.
44AC_EGREP_CPP(yes, foo)
45PKG_PROG_PKG_CONFIG()
46
47dnl  Available platforms: some of these are not public
48AM_CONDITIONAL(HAVE_PS3, test -f src/platform/ps3/ps3app.cpp)
49AM_CONDITIONAL(HAVE_XBOX, false)
50
51AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
52dnl conditional builds
53AC_ARG_ENABLE(debug,
54  [  --enable-debug          build debug versions of the game (default no)])
55AC_ARG_ENABLE(release,
56  [  --enable-release        build final release of the game (default no)])
57AC_ARG_ENABLE(experimental,
58  [  --enable-experimental   experimental build (default no)])
59
60AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h fastmath.h pthread.h)
61
62if test "${enable_debug}" = "yes"; then
63  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
64  OPT="-O"
65else
66  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
67fi
68
69if test "${enable_release}" = "yes"; then
70  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
71  REL=""
72else
73  REL="-g"
74fi
75
76if test "${enable_experimental}" = "yes"; then
77  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
78fi
79
80dnl No exceptions
81CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
82dnl Optimizations
83CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
84dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
85CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
86
87AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
88AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
89
90dnl Are we on the PS3?
91AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
92 [LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
93  dnl  For PSGL
94  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
95  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
96  if test "x${enable_debug}" = xyes; then
97    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
98  elif test "x${enable_release}" = xyes; then
99    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
100  else
101    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
102  fi
103  dnl  For the runtime Cg compiler
104  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
105  dnl  For the PNG decoder
106  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
107  dnl  For the pad library
108  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
109  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
110 [MAKE_FSELF=no])
111AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
112
113
114dnl Are we on a Direct3D 9 platform?
115ac_cv_my_have_d3d9="no"
116AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
117if test "${ac_cv_my_have_d3d9}" != "no"; then
118  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9"
119  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
120fi
121AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
122
123
124LIBS_save="$LIBS"
125LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
126AC_MSG_CHECKING(for -framework OpenGL)
127AC_TRY_LINK([], [],
128 [ac_cv_my_have_cocoa="yes"
129  AC_MSG_RESULT(yes)
130  GL_LIBS="${GL_LIBS} -framework OpenGL"
131  CXXFLAGS="${CXXFLAGS} -ObjC++"],
132 [AC_MSG_RESULT(no)])
133LIBS="$LIBS_save"
134
135
136dnl Which version of OpenGL to use?
137ac_cv_my_have_gl="no"
138PKG_CHECK_MODULES(GLES2, glesv2,
139 [ac_cv_my_have_gl="yes"
140  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
141  GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
142  GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
143 [:])
144AC_CHECK_HEADER(GLES2/gl2.h,
145 [AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
146  ac_cv_my_have_gl="yes"])
147
148PKG_CHECK_MODULES(GL, gl,
149 [ac_cv_my_have_gl="yes"
150  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
151 [:])
152
153AC_CHECK_LIB(GL, glLoadIdentity,
154 [ac_cv_my_have_gl="yes"
155  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
156  GL_LIBS="-lGL"])
157AC_CHECK_HEADER(GL/gl.h,
158 [LIBS_save="$LIBS"
159  LIBS="$LIBS -lopengl32"
160  AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
161  AC_TRY_LINK([#include <GL/gl.h>],
162   [glLoadIdentity();],
163   [ac_cv_my_have_gl="yes"
164    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
165    AC_MSG_RESULT(yes)
166    GL_LIBS="-lopengl32"],
167   [AC_MSG_RESULT(no)])
168  LIBS="$LIBS_save"])
169AC_CHECK_HEADER(PSGL/psgl.h,
170 [ac_cv_my_have_gl="yes"])
171
172if test "${ac_cv_my_have_gl}" = "no"; then
173  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
174fi
175
176dnl Use Glew?
177ac_cv_my_have_glew="no"
178PKG_CHECK_MODULES(GLEW, glew,
179 [ac_cv_my_have_glew="yes"
180  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
181  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
182 [:])
183AC_CHECK_HEADER(glew.h,
184 [LIBS_save="${LIBS}"
185  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
186  AC_MSG_CHECKING(for glewInit in -lglew32)
187  AC_TRY_LINK(
188   [#include <glew.h>],
189   [glewInit();],
190   [ac_cv_my_have_glew="yes"
191    GL_LIBS="-lglew32 ${GL_LIBS}"
192    AC_MSG_RESULT(yes)],
193   [AC_MSG_RESULT(no)])
194  LIBS="${LIBS_save}"])
195if test "${ac_cv_my_have_glew}" != "no"; then
196  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
197  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
198fi
199AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
200
201dnl Poor man's GL feature detection if all else failed.
202save_LIBS="${LIBS}"
203LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
204AC_CHECK_FUNCS(glBegin)
205LIBS="${save_LIBS}"
206
207
208dnl Use SDL? (always required on Linux or Win32)
209ac_cv_my_have_sdl="no"
210ac_cv_my_have_sdl_image="no"
211ac_cv_my_have_sdl_mixer="no"
212dnl
213dnl  First, try the proper pkg-config check
214PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
215PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
216PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
217dnl
218dnl  Then the old sdl-config method
219if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
220  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
221  if test "${SDL_CONFIG}" != "no"; then
222    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
223    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
224    ac_cv_my_have_sdl="yes"
225  fi
226fi
227dnl
228dnl  Maybe all this has failed, try direct inclusion
229save_CPPFLAGS="${CPPFLAGS}"
230save_LIBS="${LIBS}"
231CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
232LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
233AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
234AC_CHECK_HEADERS(SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
235AC_CHECK_HEADERS(SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
236AC_CHECK_LIB(SDL, main,
237 [SDL_LIBS="${SDL_LIBS} -lSDL"],
238 [ac_cv_my_have_sdl="no"])
239AC_CHECK_LIB(SDL_mixer, main,
240 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
241 [ac_cv_my_have_sdl_mixer="no"])
242AC_CHECK_LIB(SDL_image, main,
243 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
244 [ac_cv_my_have_sdl_image="no"])
245SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
246SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
247CPPFLAGS="${save_CPPFLAGS}"
248LIBS="${save_LIBS}"
249if test "${ac_cv_my_have_sdl}" = "no"; then
250  AC_MSG_WARN([SDL not found])
251else
252  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
253fi
254if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
255  AC_MSG_WARN([SDL_mixer not found])
256else
257  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
258fi
259if test "${ac_cv_my_have_sdl_image}" = "no"; then
260  AC_MSG_WARN([SDL_image not found])
261else
262  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
263fi
264AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
265AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
266AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
267
268
269dnl  Use NativeClient?
270ac_cv_my_have_nacl="no"
271AC_LANG_PUSH(C++)
272AC_CHECK_HEADERS(ppapi/cpp/instance.h, [ac_cv_my_have_nacl="yes"])
273AC_LANG_POP(C++)
274AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
275
276dnl Use EGL?
277ac_cv_my_have_egl="no"
278PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
279if test "${ac_cv_my_have_egl}" != "no"; then
280  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
281  EGL_LIBS="${EGL_LIBS} -lX11"
282fi
283AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
284
285
286dnl Use libpng? (replacement for SDL_image)
287ac_cv_my_have_libpng="no"
288PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
289if test "${ac_cv_my_have_libpng}" != "no"; then
290  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
291fi
292AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
293
294
295dnl Use Windows GDI+?
296ac_cv_my_have_gdiplus="no"
297AC_LANG_PUSH(C++)
298AC_CHECK_HEADERS(gdiplus.h,
299 [ac_cv_my_have_gdiplus="yes"
300  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
301 [ac_cv_my_have_gdiplus="no"],
302 [#include <algorithm>
303  using std::min;
304  using std::max;
305  #include <windows.h>])
306AC_LANG_POP(C++)
307if test "${ac_cv_my_have_gdiplus}" != "no"; then
308  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
309fi
310AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
311
312
313dnl Use libcaca? (required for font generation)
314ac_cv_my_have_caca="no"
315PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
316if test "${ac_cv_my_have_caca}" != "no"; then
317  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
318fi
319AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
320
321
322dnl Use libpipi? (required for video recording)
323ac_cv_my_have_pipi="no"
324PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
325if test "${ac_cv_my_have_pipi}" != "no"; then
326  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
327fi
328AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
329
330
331dnl Use GTK+? (required for the deushax editor)
332ac_cv_my_have_gtkgl="no"
333PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
334PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
335if test "${ac_cv_my_have_gtkgl}" != "no"; then
336  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
337fi
338AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
339
340
341dnl How to use the Lol Engine inside this tree
342LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
343LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
344LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
345
346AC_SUBST(MATH_LIBS)
347AC_SUBST(LOL_CFLAGS)
348AC_SUBST(LOL_LIBS)
349
350AC_CONFIG_FILES(
351 [Makefile
352  src/Makefile
353  test/Makefile
354  test/math/Makefile
355  test/sandbox/Makefile
356  test/tutorial/Makefile
357  test/xolotl/Makefile
358  gfx/Makefile
359  gfx/font/Makefile
360  tools/Makefile
361])
362AC_CONFIG_FILES(
363 [monsterz/Makefile
364])
365AC_CONFIG_FILES(
366 [deushax/Makefile
367  deushax/art/Makefile
368  deushax/art/test/Makefile
369  deushax/gfx/Makefile
370  deushax/maps/Makefile
371])
372AC_CONFIG_FILES(
373 [mrpigeon/Makefile
374])
375
376AC_OUTPUT
377
Note: See TracBrowser for help on using the repository browser.