source: trunk/configure.ac @ 1643

Last change on this file since 1643 was 1643, checked in by sam, 7 years ago

neercs: disable neercs build on Windows for now.

File size: 13.1 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9
10dnl Versioning of the separate software we ship
11LOLUNIT_VERSION=0.1
12AC_SUBST(LOLUNIT_VERSION)
13LOLREMEZ_VERSION=0.2
14AC_SUBST(LOLREMEZ_VERSION)
15
16AM_CONFIG_HEADER(config.h)
17
18AM_PROG_CC_C_O
19AC_PROG_CPP
20AC_PROG_CXX
21AC_PROG_CXXCPP
22AC_PROG_RANLIB
23
24AC_LIBTOOL_WIN32_DLL
25AM_PROG_LIBTOOL
26AC_LIBTOOL_CXX
27
28AC_C_CONST
29AC_C_INLINE
30
31dnl Ensure an error is thrown if pkg-config M4 files are not found.
32m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
33m4_pattern_forbid([^PKG_CHECK_MODULES$])
34m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
35
36dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
37if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
38  export PKG_CONFIG_LIBDIR=/dev/null
39fi
40
41dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
42dnl now otherwise it might be set in an obscure if statement. Same thing for
43dnl PKG_PROG_PKG_CONFIG which needs to be called first.
44AC_EGREP_CPP(yes, foo)
45PKG_PROG_PKG_CONFIG()
46
47AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
48dnl conditional builds
49AC_ARG_ENABLE(debug,
50  [  --enable-debug          build debug versions of the game (default no)])
51AC_ARG_ENABLE(release,
52  [  --enable-release        build final release of the game (default no)])
53AC_ARG_ENABLE(experimental,
54  [  --enable-experimental   experimental build (default no)])
55
56AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
57AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
58AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
59AC_CHECK_HEADERS(sys/wait.h)
60AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
61AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
62AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
63
64if test "${enable_debug}" = "yes"; then
65  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
66  OPT="-O"
67else
68  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
69fi
70
71if test "${enable_release}" = "yes"; then
72  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
73  REL=""
74else
75  REL="-g"
76fi
77
78if test "${enable_experimental}" = "yes"; then
79  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
80fi
81
82dnl No exceptions
83CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
84dnl Optimizations
85CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
86dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
87CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
88
89AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
90AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
91AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
92
93dnl Are we on the PS3?
94ac_cv_my_have_ps3="no"
95AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
96 [ac_cv_my_have_ps3="yes"
97  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
98  dnl  For PSGL
99  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
100  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
101  dnl  This is the old way
102  if test "x${CELLSDK}" != x -a "x${CELLSDK}" = x; then
103    CELL_SDK="${CELLSDK}"
104  fi
105  if test "x${enable_debug}" = xyes; then
106    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
107  elif test "x${enable_release}" = xyes; then
108    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
109  else
110    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
111  fi
112  dnl  For the runtime Cg compiler
113  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
114  dnl  For the PNG decoder
115  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
116  dnl  For the pad library
117  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
118  dnl  Disable this warning, it's too verbose with vector.h
119  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
120  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
121 [MAKE_FSELF=no])
122AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
123AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
124
125
126dnl  Are we on the Xbox 360?
127dnl  Answer: NO! we don't know how to build for it anyway
128AM_CONDITIONAL(USE_X360, false)
129
130
131dnl Are we on a Direct3D 9 platform?
132#ac_cv_my_have_d3d9="no"
133#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
134#if test "${ac_cv_my_have_d3d9}" != "no"; then
135#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
136#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
137#fi
138#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
139
140
141LIBS_save="$LIBS"
142LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
143AC_MSG_CHECKING(for -framework OpenGL)
144AC_TRY_LINK([], [],
145 [ac_cv_my_have_cocoa="yes"
146  AC_MSG_RESULT(yes)
147  GL_LIBS="${GL_LIBS} -framework OpenGL"
148  CXXFLAGS="${CXXFLAGS} -ObjC++"],
149 [AC_MSG_RESULT(no)])
150LIBS="$LIBS_save"
151
152
153dnl Which version of OpenGL to use?
154ac_cv_my_have_gl="no"
155PKG_CHECK_MODULES(GLES2, glesv2,
156 [ac_cv_my_have_gl="yes"
157  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
158  GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
159  GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
160 [:])
161AC_CHECK_HEADER(GLES2/gl2.h,
162 [AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
163  ac_cv_my_have_gl="yes"])
164
165PKG_CHECK_MODULES(GL, gl,
166 [ac_cv_my_have_gl="yes"
167  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
168 [:])
169
170AC_CHECK_LIB(GL, glLoadIdentity,
171 [ac_cv_my_have_gl="yes"
172  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
173  GL_LIBS="-lGL"])
174AC_CHECK_HEADER(GL/gl.h,
175 [LIBS_save="$LIBS"
176  LIBS="$LIBS -lopengl32"
177  AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
178  AC_TRY_LINK([#include <GL/gl.h>],
179   [glLoadIdentity();],
180   [ac_cv_my_have_gl="yes"
181    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
182    AC_MSG_RESULT(yes)
183    GL_LIBS="-lopengl32"],
184   [AC_MSG_RESULT(no)])
185  LIBS="$LIBS_save"])
186AC_CHECK_HEADER(PSGL/psgl.h,
187 [ac_cv_my_have_gl="yes"])
188
189if test "${ac_cv_my_have_gl}" = "no"; then
190  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
191fi
192
193dnl Use Glew?
194ac_cv_my_have_glew="no"
195PKG_CHECK_MODULES(GLEW, glew,
196 [ac_cv_my_have_glew="yes"
197  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
198  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
199 [:])
200AC_CHECK_HEADER(glew.h,
201 [LIBS_save="${LIBS}"
202  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
203  AC_MSG_CHECKING(for glewInit in -lglew32)
204  AC_TRY_LINK(
205   [#include <glew.h>],
206   [glewInit();],
207   [ac_cv_my_have_glew="yes"
208    GL_LIBS="-lglew32 ${GL_LIBS}"
209    AC_MSG_RESULT(yes)],
210   [AC_MSG_RESULT(no)])
211  LIBS="${LIBS_save}"])
212if test "${ac_cv_my_have_glew}" != "no"; then
213  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
214  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
215fi
216AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
217
218dnl Poor man's GL feature detection if all else failed.
219save_LIBS="${LIBS}"
220LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
221AC_CHECK_FUNCS(glBegin)
222LIBS="${save_LIBS}"
223
224
225dnl Use SDL? (always required on Linux or Win32)
226ac_cv_my_have_sdl="no"
227ac_cv_my_have_sdl_image="no"
228ac_cv_my_have_sdl_mixer="no"
229dnl
230dnl  First, try the proper pkg-config check
231PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
232PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
233PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
234dnl
235dnl  Then the old sdl-config method
236if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
237  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
238  if test "${SDL_CONFIG}" != "no"; then
239    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
240    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
241    ac_cv_my_have_sdl="yes"
242  fi
243fi
244dnl
245dnl  Maybe all this has failed, try direct inclusion
246save_CPPFLAGS="${CPPFLAGS}"
247save_LIBS="${LIBS}"
248CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
249LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
250AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
251AC_CHECK_HEADERS(SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
252AC_CHECK_HEADERS(SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
253AC_CHECK_LIB(SDL, main,
254 [SDL_LIBS="${SDL_LIBS} -lSDL"],
255 [ac_cv_my_have_sdl="no"])
256AC_CHECK_LIB(SDL_mixer, main,
257 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
258 [ac_cv_my_have_sdl_mixer="no"])
259AC_CHECK_LIB(SDL_image, main,
260 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
261 [ac_cv_my_have_sdl_image="no"])
262SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
263SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
264CPPFLAGS="${save_CPPFLAGS}"
265LIBS="${save_LIBS}"
266if test "${ac_cv_my_have_sdl}" = "no"; then
267  AC_MSG_WARN([SDL not found])
268else
269  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
270fi
271if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
272  AC_MSG_WARN([SDL_mixer not found])
273else
274  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
275fi
276if test "${ac_cv_my_have_sdl_image}" = "no"; then
277  AC_MSG_WARN([SDL_image not found])
278else
279  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
280fi
281AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
282AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
283AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
284
285
286dnl  Use Flex's FlexLexer.h or ours?
287ac_cv_my_have_flexlexer_h="no"
288AC_LANG_PUSH(C++)
289AC_CHECK_HEADERS(FlexLexer.h, [ac_cv_my_have_flexlexer_h="yes"])
290AC_LANG_POP(C++)
291if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
292  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/contrib/flex-2.5.35/include"
293fi
294
295
296dnl  Use NativeClient?
297ac_cv_my_have_nacl="no"
298AC_LANG_PUSH(C++)
299AC_CHECK_HEADERS(ppapi/cpp/instance.h,
300 [ac_cv_my_have_nacl="yes"
301  dnl  Disable this warning, it's too verbose with vector.h
302  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
303AC_LANG_POP(C++)
304AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
305
306
307dnl Use EGL?
308ac_cv_my_have_egl="no"
309PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
310if test "${ac_cv_my_have_egl}" != "no"; then
311  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
312  EGL_LIBS="${EGL_LIBS} -lX11"
313fi
314AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
315
316
317dnl Use libpng? (replacement for SDL_image)
318ac_cv_my_have_libpng="no"
319PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
320if test "${ac_cv_my_have_libpng}" != "no"; then
321  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
322fi
323AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
324
325
326dnl Use Windows GDI+?
327ac_cv_my_have_gdiplus="no"
328AC_LANG_PUSH(C++)
329AC_CHECK_HEADERS(gdiplus.h,
330 [ac_cv_my_have_gdiplus="yes"
331  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
332 [ac_cv_my_have_gdiplus="no"],
333 [#include <algorithm>
334  using std::min;
335  using std::max;
336  #include <windows.h>])
337AC_LANG_POP(C++)
338if test "${ac_cv_my_have_gdiplus}" != "no"; then
339  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
340fi
341AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
342
343
344dnl Use libcaca? (required for font generation)
345ac_cv_my_have_caca="no"
346PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
347if test "${ac_cv_my_have_caca}" != "no"; then
348  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
349fi
350AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
351
352
353dnl Use libpipi? (required for video recording)
354ac_cv_my_have_pipi="no"
355PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
356if test "${ac_cv_my_have_pipi}" != "no"; then
357  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
358fi
359AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
360
361
362dnl Use GTK+? (required for the deushax editor)
363ac_cv_my_have_gtkgl="no"
364PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
365PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
366if test "${ac_cv_my_have_gtkgl}" != "no"; then
367  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
368fi
369AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
370
371
372dnl  Can we build neercs?
373AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no" -a "${ac_cv_header_glob_h}" = "yes")
374
375
376dnl  LolFx compilation rule
377LOLFX_BUILD='(echo "char const *"; echo "lolfx_$(notdir $(basename $(filter %.lolfx, $^))) ="; $(SED) '"'"'s/"/\\"/g'"'"' $(filter %.lolfx, $^) | $(SED) '"'"'s/\([[^\r]]*\).*/"\1\\n"/'"'"'; echo ";") | $(CXXCOMPILE) -xc++ -c - -o $@'
378AC_SUBST(LOLFX_BUILD)
379
380
381dnl Extra libraries we may need
382AC_SUBST(MATH_LIBS)
383AC_SUBST(PAM_LIBS)
384AC_SUBST(UTIL_LIBS)
385
386dnl How to use the Lol Engine inside this tree
387LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
388LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
389LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
390
391AC_SUBST(LOL_CFLAGS)
392AC_SUBST(LOL_LIBS)
393
394
395AC_CONFIG_FILES(
396 [Makefile
397  src/Makefile
398  src/data/Makefile
399  src/data/font/Makefile
400  tutorial/Makefile
401  test/Makefile
402  test/math/Makefile
403  test/sandbox/Makefile
404  test/xolotl/Makefile
405  build/Makefile
406  binaries/Makefile
407  games/Makefile
408  tools/Makefile
409])
410AC_CONFIG_FILES(
411 [games/monsterz/Makefile
412])
413AC_CONFIG_FILES(
414 [games/deushax/Makefile
415  games/deushax/art/Makefile
416  games/deushax/art/test/Makefile
417  games/deushax/gfx/Makefile
418  games/deushax/maps/Makefile
419])
420AC_CONFIG_FILES(
421 [games/mrpigeon/Makefile
422])
423AC_CONFIG_FILES(
424 [games/orbital/Makefile
425])
426AC_CONFIG_FILES(
427 [games/ToukyDemo/Makefile
428])
429AC_CONFIG_FILES(
430 [tools/neercs/Makefile
431])
432
433AC_OUTPUT
434
Note: See TracBrowser for help on using the repository browser.