source: trunk/configure.ac @ 1653

Last change on this file since 1653 was 1653, checked in by sam, 7 years ago

build: add libSDLmain.a binaries for GUI MinGW builds; the provided static
libraries only work with the Visual Studio runtime.

File size: 13.5 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9
10dnl Versioning of the separate software we ship
11LOLUNIT_VERSION=0.1
12AC_SUBST(LOLUNIT_VERSION)
13LOLREMEZ_VERSION=0.2
14AC_SUBST(LOLREMEZ_VERSION)
15
16AM_CONFIG_HEADER(config.h)
17
18AM_PROG_CC_C_O
19AC_PROG_CPP
20AC_PROG_CXX
21AC_PROG_CXXCPP
22AC_PROG_RANLIB
23
24AC_LIBTOOL_WIN32_DLL
25AM_PROG_LIBTOOL
26AC_LIBTOOL_CXX
27
28AC_C_CONST
29AC_C_INLINE
30
31dnl Ensure an error is thrown if pkg-config M4 files are not found.
32m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
33m4_pattern_forbid([^PKG_CHECK_MODULES$])
34m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
35
36dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
37if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
38  export PKG_CONFIG_LIBDIR=/dev/null
39fi
40
41dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
42dnl now otherwise it might be set in an obscure if statement. Same thing for
43dnl PKG_PROG_PKG_CONFIG which needs to be called first.
44AC_EGREP_CPP(yes, foo)
45PKG_PROG_PKG_CONFIG()
46
47AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
48dnl conditional builds
49AC_ARG_ENABLE(debug,
50  [  --enable-debug          build debug versions of the game (default no)])
51AC_ARG_ENABLE(release,
52  [  --enable-release        build final release of the game (default no)])
53AC_ARG_ENABLE(experimental,
54  [  --enable-experimental   experimental build (default no)])
55
56AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
57AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
58AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
59AC_CHECK_HEADERS(sys/wait.h)
60AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
61AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
62AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
63
64if test "${enable_debug}" = "yes"; then
65  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
66  OPT="-O"
67else
68  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
69fi
70
71if test "${enable_release}" = "yes"; then
72  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
73  REL=""
74else
75  REL="-g"
76fi
77
78if test "${enable_experimental}" = "yes"; then
79  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
80fi
81
82dnl No exceptions
83CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
84dnl Optimizations
85CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
86dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
87CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
88
89AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
90AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
91AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
92
93dnl Are we on the PS3?
94ac_cv_my_have_ps3="no"
95AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
96 [ac_cv_my_have_ps3="yes"
97  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
98  dnl  For PSGL
99  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
100  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
101  dnl  This is the old way
102  if test "x${CELLSDK}" != x -a "x${CELLSDK}" = x; then
103    CELL_SDK="${CELLSDK}"
104  fi
105  if test "x${enable_debug}" = xyes; then
106    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
107  elif test "x${enable_release}" = xyes; then
108    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
109  else
110    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
111  fi
112  dnl  For the runtime Cg compiler
113  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
114  dnl  For the PNG decoder
115  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
116  dnl  For the pad library
117  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
118  dnl  Disable this warning, it's too verbose with vector.h
119  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
120  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
121 [MAKE_FSELF=no])
122AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
123AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
124
125
126dnl  Are we building using MinGW?
127LIBS_save="$LIBS"
128LIBS="$LIBS -mwindows -mwin32"
129AC_MSG_CHECKING(for -mwindows -mwin32)
130AC_TRY_LINK([], [],
131 [AC_MSG_RESULT(yes)
132  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
133  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
134 [AC_MSG_RESULT(no)])
135LIBS="$LIBS_save"
136
137
138dnl  Are we on the Xbox 360?
139dnl  Answer: NO! we don't know how to build for it anyway
140AM_CONDITIONAL(USE_X360, false)
141
142
143dnl Are we on a Direct3D 9 platform?
144#ac_cv_my_have_d3d9="no"
145#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
146#if test "${ac_cv_my_have_d3d9}" != "no"; then
147#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
148#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
149#fi
150#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
151
152
153LIBS_save="$LIBS"
154LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
155AC_MSG_CHECKING(for -framework OpenGL)
156AC_TRY_LINK([], [],
157 [AC_MSG_RESULT(yes)
158  GL_LIBS="${GL_LIBS} -framework OpenGL"
159  CXXFLAGS="${CXXFLAGS} -ObjC++"],
160 [AC_MSG_RESULT(no)])
161LIBS="$LIBS_save"
162
163
164dnl Which version of OpenGL to use?
165ac_cv_my_have_gl="no"
166PKG_CHECK_MODULES(GLES2, glesv2,
167 [ac_cv_my_have_gl="yes"
168  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
169  GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
170  GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
171 [:])
172AC_CHECK_HEADER(GLES2/gl2.h,
173 [AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
174  ac_cv_my_have_gl="yes"])
175
176PKG_CHECK_MODULES(GL, gl,
177 [ac_cv_my_have_gl="yes"
178  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
179 [:])
180
181AC_CHECK_LIB(GL, glLoadIdentity,
182 [ac_cv_my_have_gl="yes"
183  AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
184  GL_LIBS="-lGL"])
185AC_CHECK_HEADER(GL/gl.h,
186 [LIBS_save="$LIBS"
187  LIBS="$LIBS -lopengl32"
188  AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
189  AC_TRY_LINK([#include <GL/gl.h>],
190   [glLoadIdentity();],
191   [ac_cv_my_have_gl="yes"
192    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
193    AC_MSG_RESULT(yes)
194    GL_LIBS="-lopengl32"],
195   [AC_MSG_RESULT(no)])
196  LIBS="$LIBS_save"])
197AC_CHECK_HEADER(PSGL/psgl.h,
198 [ac_cv_my_have_gl="yes"])
199
200if test "${ac_cv_my_have_gl}" = "no"; then
201  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
202fi
203
204dnl Use Glew?
205ac_cv_my_have_glew="no"
206PKG_CHECK_MODULES(GLEW, glew,
207 [ac_cv_my_have_glew="yes"
208  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
209  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
210 [:])
211AC_CHECK_HEADER(glew.h,
212 [LIBS_save="${LIBS}"
213  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
214  AC_MSG_CHECKING(for glewInit in -lglew32)
215  AC_TRY_LINK(
216   [#include <glew.h>],
217   [glewInit();],
218   [ac_cv_my_have_glew="yes"
219    GL_LIBS="-lglew32 ${GL_LIBS}"
220    AC_MSG_RESULT(yes)],
221   [AC_MSG_RESULT(no)])
222  LIBS="${LIBS_save}"])
223if test "${ac_cv_my_have_glew}" != "no"; then
224  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
225  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
226fi
227AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
228
229dnl Poor man's GL feature detection if all else failed.
230save_LIBS="${LIBS}"
231LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
232AC_CHECK_FUNCS(glBegin)
233LIBS="${save_LIBS}"
234
235
236dnl Use SDL? (always required on Linux or Win32)
237ac_cv_my_have_sdl="no"
238ac_cv_my_have_sdl_image="no"
239ac_cv_my_have_sdl_mixer="no"
240dnl
241dnl  First, try the proper pkg-config check
242PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
243PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
244PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
245dnl
246dnl  Then the old sdl-config method
247if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
248  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
249  if test "${SDL_CONFIG}" != "no"; then
250    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
251    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
252    ac_cv_my_have_sdl="yes"
253  fi
254fi
255dnl
256dnl  Maybe all this has failed, try direct inclusion
257save_CPPFLAGS="${CPPFLAGS}"
258save_LIBS="${LIBS}"
259CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
260LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
261AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
262AC_CHECK_HEADERS(SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
263AC_CHECK_HEADERS(SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
264AC_CHECK_LIB(SDL, main,
265 [SDL_LIBS="${SDL_LIBS} -lSDL"],
266 [ac_cv_my_have_sdl="no"])
267AC_CHECK_LIB(SDLmain, main,
268 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
269AC_CHECK_LIB(SDL_mixer, main,
270 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
271 [ac_cv_my_have_sdl_mixer="no"])
272AC_CHECK_LIB(SDL_image, main,
273 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
274 [ac_cv_my_have_sdl_image="no"])
275SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
276SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
277CPPFLAGS="${save_CPPFLAGS}"
278LIBS="${save_LIBS}"
279if test "${ac_cv_my_have_sdl}" = "no"; then
280  AC_MSG_WARN([SDL not found])
281else
282  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
283fi
284if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
285  AC_MSG_WARN([SDL_mixer not found])
286else
287  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
288fi
289if test "${ac_cv_my_have_sdl_image}" = "no"; then
290  AC_MSG_WARN([SDL_image not found])
291else
292  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
293fi
294AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
295AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
296AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
297
298
299dnl  Use Flex's FlexLexer.h or ours?
300ac_cv_my_have_flexlexer_h="no"
301AC_LANG_PUSH(C++)
302AC_CHECK_HEADERS(FlexLexer.h, [ac_cv_my_have_flexlexer_h="yes"])
303AC_LANG_POP(C++)
304if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
305  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/contrib/flex-2.5.35/include"
306fi
307
308
309dnl  Use NativeClient?
310ac_cv_my_have_nacl="no"
311AC_LANG_PUSH(C++)
312AC_CHECK_HEADERS(ppapi/cpp/instance.h,
313 [ac_cv_my_have_nacl="yes"
314  dnl  Disable this warning, it's too verbose with vector.h
315  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
316AC_LANG_POP(C++)
317AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
318
319
320dnl Use EGL?
321ac_cv_my_have_egl="no"
322PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
323if test "${ac_cv_my_have_egl}" != "no"; then
324  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
325  EGL_LIBS="${EGL_LIBS} -lX11"
326fi
327AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
328
329
330dnl Use libpng? (replacement for SDL_image)
331ac_cv_my_have_libpng="no"
332PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
333if test "${ac_cv_my_have_libpng}" != "no"; then
334  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
335fi
336AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
337
338
339dnl Use Windows GDI+?
340ac_cv_my_have_gdiplus="no"
341AC_LANG_PUSH(C++)
342AC_CHECK_HEADERS(gdiplus.h,
343 [ac_cv_my_have_gdiplus="yes"
344  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
345 [ac_cv_my_have_gdiplus="no"],
346 [#include <algorithm>
347  using std::min;
348  using std::max;
349  #include <windows.h>])
350AC_LANG_POP(C++)
351if test "${ac_cv_my_have_gdiplus}" != "no"; then
352  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
353fi
354AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
355
356
357dnl Use libcaca? (required for font generation)
358ac_cv_my_have_caca="no"
359PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
360if test "${ac_cv_my_have_caca}" != "no"; then
361  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
362fi
363AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
364
365
366dnl Use libpipi? (required for video recording)
367ac_cv_my_have_pipi="no"
368PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
369if test "${ac_cv_my_have_pipi}" != "no"; then
370  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
371fi
372AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
373
374
375dnl Use GTK+? (required for the deushax editor)
376ac_cv_my_have_gtkgl="no"
377PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
378PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
379if test "${ac_cv_my_have_gtkgl}" != "no"; then
380  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
381fi
382AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
383
384
385dnl  Can we build neercs?
386AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no" -a "${ac_cv_header_glob_h}" = "yes")
387
388
389dnl  LolFx compilation rule
390LOLFX_BUILD='(echo "char const *"; echo "lolfx_$(notdir $(basename $(filter %.lolfx, $^))) ="; $(SED) '"'"'s/"/\\"/g'"'"' $(filter %.lolfx, $^) | $(SED) '"'"'s/\([[^\r]]*\).*/"\1\\n"/'"'"'; echo ";") | $(CXXCOMPILE) -xc++ -c - -o $@'
391AC_SUBST(LOLFX_BUILD)
392
393
394dnl Extra libraries we may need
395AC_SUBST(MATH_LIBS)
396AC_SUBST(PAM_LIBS)
397AC_SUBST(UTIL_LIBS)
398
399dnl How to use the Lol Engine inside this tree
400LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
401LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
402LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
403
404AC_SUBST(LOL_CFLAGS)
405AC_SUBST(LOL_LIBS)
406
407
408AC_CONFIG_FILES(
409 [Makefile
410  src/Makefile
411  src/data/Makefile
412  src/data/font/Makefile
413  tutorial/Makefile
414  test/Makefile
415  test/math/Makefile
416  test/sandbox/Makefile
417  test/xolotl/Makefile
418  build/Makefile
419  binaries/Makefile
420  games/Makefile
421  tools/Makefile
422])
423AC_CONFIG_FILES(
424 [games/monsterz/Makefile
425])
426AC_CONFIG_FILES(
427 [games/deushax/Makefile
428  games/deushax/art/Makefile
429  games/deushax/art/test/Makefile
430  games/deushax/gfx/Makefile
431  games/deushax/maps/Makefile
432])
433AC_CONFIG_FILES(
434 [games/mrpigeon/Makefile
435])
436AC_CONFIG_FILES(
437 [games/orbital/Makefile
438])
439AC_CONFIG_FILES(
440 [games/ToukyDemo/Makefile
441])
442AC_CONFIG_FILES(
443 [tools/neercs/Makefile
444])
445
446AC_OUTPUT
447
Note: See TracBrowser for help on using the repository browser.