source: trunk/configure.ac @ 1678

Last change on this file since 1678 was 1678, checked in by sam, 7 years ago

build: fix broken Glew detection on OS X.

File size: 15.0 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9
10dnl Versioning of the separate software we ship
11LOLUNIT_VERSION=0.1
12AC_SUBST(LOLUNIT_VERSION)
13LOLREMEZ_VERSION=0.2
14AC_SUBST(LOLREMEZ_VERSION)
15
16AM_CONFIG_HEADER(config.h)
17
18AM_PROG_CC_C_O
19AC_PROG_CPP
20AC_PROG_CXX
21AC_PROG_CXXCPP
22AC_PROG_RANLIB
23
24AC_LIBTOOL_WIN32_DLL
25AM_PROG_LIBTOOL
26AC_LIBTOOL_CXX
27
28AC_C_CONST
29AC_C_INLINE
30
31dnl Ensure an error is thrown if pkg-config M4 files are not found.
32m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
33m4_pattern_forbid([^PKG_CHECK_MODULES$])
34m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
35
36dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
37if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
38  export PKG_CONFIG_LIBDIR=/dev/null
39fi
40
41dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
42dnl now otherwise it might be set in an obscure if statement. Same thing for
43dnl PKG_PROG_PKG_CONFIG which needs to be called first.
44AC_EGREP_CPP(yes, foo)
45PKG_PROG_PKG_CONFIG()
46
47AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
48dnl conditional builds
49AC_ARG_ENABLE(debug,
50  [  --enable-debug          build debug versions of the game (default no)])
51AC_ARG_ENABLE(release,
52  [  --enable-release        build final release of the game (default no)])
53AC_ARG_ENABLE(experimental,
54  [  --enable-experimental   experimental build (default no)])
55
56AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
57AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
58AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
59AC_CHECK_HEADERS(sys/wait.h)
60AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
61AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
62AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
63
64if test "${enable_debug}" = "yes"; then
65  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
66  OPT="-O"
67else
68  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
69fi
70
71if test "${enable_release}" = "yes"; then
72  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
73  REL=""
74else
75  REL="-g"
76fi
77
78if test "${enable_experimental}" = "yes"; then
79  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
80fi
81
82dnl No exceptions
83CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
84dnl Optimizations
85CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
86dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
87CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
88
89AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
90AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
91AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
92
93dnl Are we on the PS3?
94ac_cv_my_have_ps3="no"
95AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
96 [ac_cv_my_have_ps3="yes"
97  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
98  dnl  For PSGL
99  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
100  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
101  dnl  This is the old way
102  if test "x${CELLSDK}" != x -a "x${CELLSDK}" = x; then
103    CELL_SDK="${CELLSDK}"
104  fi
105  if test "x${enable_debug}" = xyes; then
106    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
107  elif test "x${enable_release}" = xyes; then
108    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
109  else
110    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
111  fi
112  dnl  For the runtime Cg compiler
113  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
114  dnl  For the PNG decoder
115  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
116  dnl  For the pad library
117  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
118  dnl  Disable this warning, it's too verbose with vector.h
119  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
120  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
121 [MAKE_FSELF=no])
122AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
123AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
124
125
126dnl  Are we building using MinGW?
127LIBS_save="$LIBS"
128LIBS="$LIBS -mwindows -mwin32"
129AC_MSG_CHECKING(for -mwindows -mwin32)
130AC_TRY_LINK([], [],
131 [AC_MSG_RESULT(yes)
132  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
133  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
134 [AC_MSG_RESULT(no)])
135LIBS="$LIBS_save"
136
137
138dnl  Are we on the Xbox 360?
139dnl  Answer: NO! we don't know how to build for it anyway
140AM_CONDITIONAL(USE_X360, false)
141
142
143dnl Are we on a Direct3D 9 platform?
144#ac_cv_my_have_d3d9="no"
145#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
146#if test "${ac_cv_my_have_d3d9}" != "no"; then
147#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
148#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
149#fi
150#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
151
152
153dnl  Find which version of OpenGL to use
154ac_cv_my_have_gl="no"
155ac_cv_my_stop_looking_for_gl="no"
156
157if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
158  LIBS_save="$LIBS"
159  LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
160  AC_MSG_CHECKING(for -framework OpenGL)
161  AC_TRY_LINK([], [],
162   [AC_MSG_RESULT(yes)
163    GL_LIBS="${GL_LIBS} -framework OpenGL"
164    CXXFLAGS="${CXXFLAGS} -ObjC++"],
165   [AC_MSG_RESULT(no)])
166  LIBS="$LIBS_save"
167fi
168
169dnl  Use the Raspberry Pi libraries?
170if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
171  AC_CHECK_HEADERS(bcm_host.h,
172   [AC_CHECK_LIB(vcos, main,
173     [ac_cv_my_have_gl="yes"
174      ac_cv_my_stop_looking_for_gl="yes"
175      AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
176      dnl  FIXME: -lEGL does not belong here but the configure test fails
177      dnl  when cross-compiling, so we add it manually here.
178      GL_LIBS="${GL_LIBS} -lGLESv2 -lEGL -lvcos -lvchiq_arm -lbcm_host"])])
179fi
180
181dnl  Use the PS3 PSGL?
182if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
183  AC_CHECK_HEADERS(PSGL/psgl.h,
184   [ac_cv_my_have_gl="yes"
185    ac_cv_my_stop_looking_for_gl="yes"])
186fi
187
188if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
189  PKG_CHECK_MODULES(GLES2, glesv2,
190   [ac_cv_my_have_gl="yes"
191    AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
192    GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
193    GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
194   [:])
195fi
196
197if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
198  AC_CHECK_HEADER(GLES2/gl2.h,
199   [AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
200    ac_cv_my_have_gl="yes"])
201fi
202
203if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
204  PKG_CHECK_MODULES(GL, gl,
205   [ac_cv_my_have_gl="yes"
206    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
207   [:])
208fi
209
210if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
211  AC_CHECK_LIB(GL, glLoadIdentity,
212   [ac_cv_my_have_gl="yes"
213    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
214    GL_LIBS="-lGL"])
215fi
216
217if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
218  AC_CHECK_HEADER(GL/gl.h,
219   [LIBS_save="$LIBS"
220    LIBS="$LIBS -lopengl32"
221    AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
222    AC_TRY_LINK([#include <GL/gl.h>],
223     [glLoadIdentity();],
224     [ac_cv_my_have_gl="yes"
225      AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
226      AC_MSG_RESULT(yes)
227      GL_LIBS="-lopengl32"],
228     [AC_MSG_RESULT(no)])
229    LIBS="$LIBS_save"])
230fi
231
232if test "${ac_cv_my_have_gl}" = "no"; then
233  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
234fi
235
236
237dnl Use Glew?
238ac_cv_my_have_glew="no"
239PKG_CHECK_MODULES(GLEW, glew,
240 [ac_cv_my_have_glew="yes"
241  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
242  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
243 [:])
244AC_CHECK_HEADER(glew.h,
245 [LIBS_save="${LIBS}"
246  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
247  AC_MSG_CHECKING(for glewInit in -lglew32)
248  AC_TRY_LINK(
249   [#include <glew.h>],
250   [glewInit();],
251   [ac_cv_my_have_glew="yes"
252    GL_LIBS="-lglew32 ${GL_LIBS}"
253    AC_MSG_RESULT(yes)],
254   [AC_MSG_RESULT(no)])
255  LIBS="${LIBS_save}"])
256if test "${ac_cv_my_have_glew}" != "no"; then
257  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
258  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
259fi
260AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
261
262dnl Poor man's GL feature detection if all else failed.
263save_LIBS="${LIBS}"
264LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
265AC_CHECK_FUNCS(glBegin)
266LIBS="${save_LIBS}"
267
268
269dnl Use SDL? (always required on Linux or Win32)
270ac_cv_my_have_sdl="no"
271ac_cv_my_have_sdl_image="no"
272ac_cv_my_have_sdl_mixer="no"
273dnl
274dnl  First, try the proper pkg-config check
275PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
276PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
277PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
278dnl
279dnl  Then the old sdl-config method
280if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
281  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
282  if test "${SDL_CONFIG}" != "no"; then
283    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
284    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
285    ac_cv_my_have_sdl="yes"
286  fi
287fi
288dnl
289dnl  Maybe all this has failed, try direct inclusion
290save_CPPFLAGS="${CPPFLAGS}"
291save_LIBS="${LIBS}"
292CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
293LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
294AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
295AC_CHECK_HEADERS(SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
296AC_CHECK_HEADERS(SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
297AC_CHECK_LIB(SDL, main,
298 [SDL_LIBS="${SDL_LIBS} -lSDL"],
299 [ac_cv_my_have_sdl="no"])
300AC_CHECK_LIB(SDLmain, main,
301 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
302AC_CHECK_LIB(SDL_mixer, main,
303 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
304 [ac_cv_my_have_sdl_mixer="no"])
305AC_CHECK_LIB(SDL_image, main,
306 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
307 [ac_cv_my_have_sdl_image="no"])
308SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
309SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
310CPPFLAGS="${save_CPPFLAGS}"
311LIBS="${save_LIBS}"
312if test "${ac_cv_my_have_sdl}" = "no"; then
313  AC_MSG_WARN([SDL not found])
314else
315  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
316fi
317if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
318  AC_MSG_WARN([SDL_mixer not found])
319else
320  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
321fi
322if test "${ac_cv_my_have_sdl_image}" = "no"; then
323  AC_MSG_WARN([SDL_image not found])
324else
325  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
326fi
327AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
328AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
329AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
330
331
332dnl  Use Flex's FlexLexer.h or ours?
333ac_cv_my_have_flexlexer_h="no"
334AC_LANG_PUSH(C++)
335AC_CHECK_HEADERS(FlexLexer.h, [ac_cv_my_have_flexlexer_h="yes"])
336AC_LANG_POP(C++)
337if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
338  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/contrib/flex-2.5.35/include"
339fi
340
341
342dnl  Use NativeClient?
343ac_cv_my_have_nacl="no"
344AC_LANG_PUSH(C++)
345AC_CHECK_HEADERS(ppapi/cpp/instance.h,
346 [ac_cv_my_have_nacl="yes"
347  dnl  Disable this warning, it's too verbose with vector.h
348  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
349AC_LANG_POP(C++)
350AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
351
352
353dnl  Use EGL?
354ac_cv_my_have_egl="no"
355PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
356if test "${ac_cv_my_have_egl}" != "no"; then
357  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
358  EGL_LIBS="${EGL_LIBS} -lX11"
359fi
360AC_CHECK_LIB(EGL, main,
361 [ac_cv_my_have_egl="yes"
362  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
363  EGL_LIBS="-lEGL"])
364dnl  Raspberry Pi is different, check for it with extra libs; also we
365dnl  look for a different function to bypass autoconf caching
366AC_CHECK_LIB(EGL, eglGetDisplay,
367 [ac_cv_my_have_egl="yes"
368  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
369  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
370 [:],
371 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
372AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
373
374
375dnl Use libpng? (replacement for SDL_image)
376ac_cv_my_have_libpng="no"
377PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
378if test "${ac_cv_my_have_libpng}" != "no"; then
379  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
380fi
381AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
382
383
384dnl Use Windows GDI+?
385ac_cv_my_have_gdiplus="no"
386AC_LANG_PUSH(C++)
387AC_CHECK_HEADERS(gdiplus.h,
388 [ac_cv_my_have_gdiplus="yes"
389  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
390 [ac_cv_my_have_gdiplus="no"],
391 [#include <algorithm>
392  using std::min;
393  using std::max;
394  #include <windows.h>])
395AC_LANG_POP(C++)
396if test "${ac_cv_my_have_gdiplus}" != "no"; then
397  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
398fi
399AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
400
401
402dnl Use libcaca? (required for font generation)
403ac_cv_my_have_caca="no"
404PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
405if test "${ac_cv_my_have_caca}" != "no"; then
406  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
407fi
408AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
409
410
411dnl Use libpipi? (required for video recording)
412ac_cv_my_have_pipi="no"
413PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
414if test "${ac_cv_my_have_pipi}" != "no"; then
415  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
416fi
417AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
418
419
420dnl Use GTK+? (required for the deushax editor)
421ac_cv_my_have_gtkgl="no"
422PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
423PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
424if test "${ac_cv_my_have_gtkgl}" != "no"; then
425  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
426fi
427AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
428
429
430dnl  Can we build neercs?
431AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no" -a "${ac_cv_header_glob_h}" = "yes")
432
433
434dnl  LolFx compilation rule
435LOLFX_BUILD='(echo "char const *"; echo "lolfx_$(notdir $(basename $(filter %.lolfx, $^))) ="; $(SED) '"'"'s/"/\\"/g'"'"' $(filter %.lolfx, $^) | $(SED) '"'"'s/\([[^\r]]*\).*/"\1\\n"/'"'"'; echo ";") | $(CXXCOMPILE) -xc++ -c - -o $@'
436AC_SUBST(LOLFX_BUILD)
437
438
439dnl Extra libraries we may need
440AC_SUBST(MATH_LIBS)
441AC_SUBST(PAM_LIBS)
442AC_SUBST(UTIL_LIBS)
443
444dnl How to use the Lol Engine inside this tree
445LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
446LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
447LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
448
449AC_SUBST(LOL_CFLAGS)
450AC_SUBST(LOL_LIBS)
451
452
453AC_CONFIG_FILES(
454 [Makefile
455  src/Makefile
456  src/data/Makefile
457  src/data/font/Makefile
458  tutorial/Makefile
459  test/Makefile
460  test/math/Makefile
461  test/sandbox/Makefile
462  test/xolotl/Makefile
463  build/Makefile
464  binaries/Makefile
465  games/Makefile
466  tools/Makefile
467])
468AC_CONFIG_FILES(
469 [games/monsterz/Makefile
470])
471AC_CONFIG_FILES(
472 [games/deushax/Makefile
473  games/deushax/art/Makefile
474  games/deushax/art/test/Makefile
475  games/deushax/gfx/Makefile
476  games/deushax/maps/Makefile
477])
478AC_CONFIG_FILES(
479 [games/mrpigeon/Makefile
480])
481AC_CONFIG_FILES(
482 [games/orbital/Makefile
483])
484AC_CONFIG_FILES(
485 [games/ToukyDemo/Makefile
486])
487AC_CONFIG_FILES(
488 [tools/neercs/Makefile
489])
490
491AC_OUTPUT
492
Note: See TracBrowser for help on using the repository browser.