source: trunk/configure.ac @ 1684

Last change on this file since 1684 was 1684, checked in by sam, 7 years ago

build: switch the Android native build rules to autoconf; still a bit rough
but we can now create shared objects for each project; only the testsuite
is not building properly because of issues with STLport, and EglApp is
deactivated because AndroidApp should have precedence.

File size: 15.3 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9
10dnl Versioning of the separate software we ship
11LOLUNIT_VERSION=0.1
12AC_SUBST(LOLUNIT_VERSION)
13LOLREMEZ_VERSION=0.2
14AC_SUBST(LOLREMEZ_VERSION)
15
16AM_CONFIG_HEADER(config.h)
17
18AM_PROG_CC_C_O
19AC_PROG_CPP
20AC_PROG_CXX
21AC_PROG_CXXCPP
22AC_PROG_RANLIB
23
24AC_LIBTOOL_WIN32_DLL
25AM_PROG_LIBTOOL
26AC_LIBTOOL_CXX
27
28AC_C_CONST
29AC_C_INLINE
30
31dnl Ensure an error is thrown if pkg-config M4 files are not found.
32m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
33m4_pattern_forbid([^PKG_CHECK_MODULES$])
34m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
35
36dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
37if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
38  export PKG_CONFIG_LIBDIR=/dev/null
39fi
40
41dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
42dnl now otherwise it might be set in an obscure if statement. Same thing for
43dnl PKG_PROG_PKG_CONFIG which needs to be called first.
44AC_EGREP_CPP(yes, foo)
45PKG_PROG_PKG_CONFIG()
46
47AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
48dnl conditional builds
49AC_ARG_ENABLE(debug,
50  [  --enable-debug          build debug versions of the game (default no)])
51AC_ARG_ENABLE(release,
52  [  --enable-release        build final release of the game (default no)])
53AC_ARG_ENABLE(experimental,
54  [  --enable-experimental   experimental build (default no)])
55
56AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
57AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
58AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
59AC_CHECK_HEADERS(sys/wait.h)
60AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
61AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
62AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
63
64if test "${enable_debug}" = "yes"; then
65  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
66  OPT="-O"
67else
68  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
69fi
70
71if test "${enable_release}" = "yes"; then
72  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
73  REL=""
74else
75  REL="-g"
76fi
77
78if test "${enable_experimental}" = "yes"; then
79  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
80fi
81
82dnl No exceptions
83CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
84dnl Optimizations
85CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
86dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
87CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
88
89AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
90AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
91AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
92
93dnl Are we on the PS3?
94ac_cv_my_have_ps3="no"
95AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
96 [ac_cv_my_have_ps3="yes"
97  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
98  dnl  For PSGL
99  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
100  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
101  dnl  This is the old way
102  if test "x${CELLSDK}" != x -a "x${CELLSDK}" = x; then
103    CELL_SDK="${CELLSDK}"
104  fi
105  if test "x${enable_debug}" = xyes; then
106    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
107  elif test "x${enable_release}" = xyes; then
108    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
109  else
110    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
111  fi
112  dnl  For the runtime Cg compiler
113  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
114  dnl  For the PNG decoder
115  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
116  dnl  For the pad library
117  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
118  dnl  Disable this warning, it's too verbose with vector.h
119  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
120  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
121 [MAKE_FSELF=no])
122AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
123AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
124
125
126dnl  Are we building using MinGW?
127LIBS_save="$LIBS"
128LIBS="$LIBS -mwindows -mwin32"
129AC_MSG_CHECKING(for -mwindows -mwin32)
130AC_TRY_LINK([], [],
131 [AC_MSG_RESULT(yes)
132  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
133  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
134 [AC_MSG_RESULT(no)])
135LIBS="$LIBS_save"
136
137
138dnl  Are we on the Xbox 360?
139dnl  Answer: NO! we don't know how to build for it anyway
140AM_CONDITIONAL(USE_X360, false)
141
142
143dnl Are we on a Direct3D 9 platform?
144#ac_cv_my_have_d3d9="no"
145#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
146#if test "${ac_cv_my_have_d3d9}" != "no"; then
147#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
148#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
149#fi
150#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
151
152
153dnl  Find which version of OpenGL to use
154ac_cv_my_have_gl="no"
155ac_cv_my_stop_looking_for_gl="no"
156
157if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
158  LIBS_save="$LIBS"
159  LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
160  AC_MSG_CHECKING(for -framework OpenGL)
161  AC_TRY_LINK([], [],
162   [AC_MSG_RESULT(yes)
163    GL_LIBS="${GL_LIBS} -framework OpenGL"
164    CXXFLAGS="${CXXFLAGS} -ObjC++"],
165   [AC_MSG_RESULT(no)])
166  LIBS="$LIBS_save"
167fi
168
169dnl  Use the Raspberry Pi libraries?
170if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
171  AC_CHECK_HEADERS(bcm_host.h,
172   [AC_CHECK_LIB(vcos, main,
173     [ac_cv_my_have_gl="yes"
174      ac_cv_my_stop_looking_for_gl="yes"
175      AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
176      dnl  FIXME: -lEGL does not belong here but the configure test fails
177      dnl  when cross-compiling, so we add it manually here.
178      GL_LIBS="${GL_LIBS} -lGLESv2 -lEGL -lvcos -lvchiq_arm -lbcm_host"])])
179fi
180
181dnl  Use the PS3 PSGL?
182if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
183  AC_CHECK_HEADERS(PSGL/psgl.h,
184   [ac_cv_my_have_gl="yes"
185    ac_cv_my_stop_looking_for_gl="yes"])
186fi
187
188if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
189  PKG_CHECK_MODULES(GLES2, glesv2,
190   [ac_cv_my_have_gl="yes"
191    AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
192    GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
193    GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
194   [:])
195fi
196
197if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
198  AC_CHECK_HEADER(GLES2/gl2.h,
199   [ac_cv_my_have_gl="yes"
200    AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
201    AC_CHECK_LIB(GLESv2, glEnable,
202     [GL_LIBS="${GL_LIBS} -lGLESv2"])])
203fi
204
205if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
206  PKG_CHECK_MODULES(GL, gl,
207   [ac_cv_my_have_gl="yes"
208    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
209   [:])
210fi
211
212if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
213  AC_CHECK_LIB(GL, glEnable,
214   [ac_cv_my_have_gl="yes"
215    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
216    GL_LIBS="-lGL"])
217fi
218
219if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
220  AC_CHECK_HEADER(GL/gl.h,
221   [LIBS_save="$LIBS"
222    LIBS="$LIBS -lopengl32"
223    AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
224    AC_TRY_LINK([#include <GL/gl.h>],
225     [glLoadIdentity();],
226     [ac_cv_my_have_gl="yes"
227      AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
228      AC_MSG_RESULT(yes)
229      GL_LIBS="-lopengl32"],
230     [AC_MSG_RESULT(no)])
231    LIBS="$LIBS_save"])
232fi
233
234if test "${ac_cv_my_have_gl}" = "no"; then
235  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
236fi
237
238
239dnl Use Glew?
240ac_cv_my_have_glew="no"
241PKG_CHECK_MODULES(GLEW, glew,
242 [ac_cv_my_have_glew="yes"
243  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
244  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
245 [:])
246AC_CHECK_HEADER(glew.h,
247 [LIBS_save="${LIBS}"
248  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
249  AC_MSG_CHECKING(for glewInit in -lglew32)
250  AC_TRY_LINK(
251   [#include <glew.h>],
252   [glewInit();],
253   [ac_cv_my_have_glew="yes"
254    GL_LIBS="-lglew32 ${GL_LIBS}"
255    AC_MSG_RESULT(yes)],
256   [AC_MSG_RESULT(no)])
257  LIBS="${LIBS_save}"])
258if test "${ac_cv_my_have_glew}" != "no"; then
259  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
260  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
261fi
262AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
263
264dnl Poor man's GL feature detection if all else failed.
265save_LIBS="${LIBS}"
266LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
267AC_CHECK_FUNCS(glBegin)
268LIBS="${save_LIBS}"
269
270
271dnl Use SDL? (always required on Linux or Win32)
272ac_cv_my_have_sdl="no"
273ac_cv_my_have_sdl_image="no"
274ac_cv_my_have_sdl_mixer="no"
275dnl
276dnl  First, try the proper pkg-config check
277PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
278PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
279PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
280dnl
281dnl  Then the old sdl-config method
282if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
283  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
284  if test "${SDL_CONFIG}" != "no"; then
285    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
286    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
287    ac_cv_my_have_sdl="yes"
288  fi
289fi
290dnl
291dnl  Maybe all this has failed, try direct inclusion
292save_CPPFLAGS="${CPPFLAGS}"
293save_LIBS="${LIBS}"
294CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
295LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
296AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
297AC_CHECK_HEADERS(SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
298AC_CHECK_HEADERS(SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
299AC_CHECK_LIB(SDL, main,
300 [SDL_LIBS="${SDL_LIBS} -lSDL"],
301 [ac_cv_my_have_sdl="no"])
302AC_CHECK_LIB(SDLmain, main,
303 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
304AC_CHECK_LIB(SDL_mixer, main,
305 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
306 [ac_cv_my_have_sdl_mixer="no"])
307AC_CHECK_LIB(SDL_image, main,
308 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
309 [ac_cv_my_have_sdl_image="no"])
310SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
311SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
312CPPFLAGS="${save_CPPFLAGS}"
313LIBS="${save_LIBS}"
314if test "${ac_cv_my_have_sdl}" = "no"; then
315  AC_MSG_WARN([SDL not found])
316else
317  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
318fi
319if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
320  AC_MSG_WARN([SDL_mixer not found])
321else
322  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
323fi
324if test "${ac_cv_my_have_sdl_image}" = "no"; then
325  AC_MSG_WARN([SDL_image not found])
326else
327  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
328fi
329AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
330AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
331AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
332
333
334dnl  Use Flex's FlexLexer.h or ours?
335ac_cv_my_have_flexlexer_h="no"
336AC_LANG_PUSH(C++)
337AC_CHECK_HEADERS(FlexLexer.h, [ac_cv_my_have_flexlexer_h="yes"])
338AC_LANG_POP(C++)
339if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
340  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/contrib/flex-2.5.35/include"
341fi
342
343
344dnl  Use NativeClient?
345ac_cv_my_have_nacl="no"
346AC_LANG_PUSH(C++)
347AC_CHECK_HEADERS(ppapi/cpp/instance.h,
348 [ac_cv_my_have_nacl="yes"
349  dnl  Disable this warning, it's too verbose with vector.h
350  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
351AC_LANG_POP(C++)
352AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
353
354
355dnl  Use Android? FIXME: super hacks!
356ac_cv_my_have_android="no"
357AC_CHECK_LIB(log, __android_log_vprint,
358 [ac_cv_my_have_android="yes"
359  LOL_LIBS="${LOL_LIBS} -llog -module"])
360AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
361
362
363dnl  Use EGL?
364ac_cv_my_have_egl="no"
365PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
366if test "${ac_cv_my_have_egl}" != "no"; then
367  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
368  EGL_LIBS="${EGL_LIBS} -lX11"
369fi
370AC_CHECK_LIB(EGL, main,
371 [ac_cv_my_have_egl="yes"
372  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
373  EGL_LIBS="-lEGL"])
374dnl  Raspberry Pi is different, check for it with extra libs; also we
375dnl  look for a different function to bypass autoconf caching
376AC_CHECK_LIB(EGL, eglGetDisplay,
377 [ac_cv_my_have_egl="yes"
378  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
379  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
380 [:],
381 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
382AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
383
384
385dnl Use libpng? (replacement for SDL_image)
386ac_cv_my_have_libpng="no"
387PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
388if test "${ac_cv_my_have_libpng}" != "no"; then
389  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
390fi
391AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
392
393
394dnl Use Windows GDI+?
395ac_cv_my_have_gdiplus="no"
396AC_LANG_PUSH(C++)
397AC_CHECK_HEADERS(gdiplus.h,
398 [ac_cv_my_have_gdiplus="yes"
399  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
400 [ac_cv_my_have_gdiplus="no"],
401 [#include <algorithm>
402  using std::min;
403  using std::max;
404  #include <windows.h>])
405AC_LANG_POP(C++)
406if test "${ac_cv_my_have_gdiplus}" != "no"; then
407  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
408fi
409AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
410
411
412dnl Use libcaca? (required for font generation)
413ac_cv_my_have_caca="no"
414PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
415if test "${ac_cv_my_have_caca}" != "no"; then
416  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
417fi
418AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
419
420
421dnl Use libpipi? (required for video recording)
422ac_cv_my_have_pipi="no"
423PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
424if test "${ac_cv_my_have_pipi}" != "no"; then
425  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
426fi
427AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
428
429
430dnl Use GTK+? (required for the deushax editor)
431ac_cv_my_have_gtkgl="no"
432PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
433PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
434if test "${ac_cv_my_have_gtkgl}" != "no"; then
435  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
436fi
437AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
438
439
440dnl  Can we build neercs?
441AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no" -a "${ac_cv_header_glob_h}" = "yes")
442
443
444dnl  LolFx compilation rule
445LOLFX_BUILD='(echo "char const *"; echo "lolfx_$(notdir $(basename $(filter %.lolfx, $^))) ="; $(SED) '"'"'s/"/\\"/g'"'"' $(filter %.lolfx, $^) | $(SED) '"'"'s/\([[^\r]]*\).*/"\1\\n"/'"'"'; echo ";") | $(CXXCOMPILE) -xc++ -c - -o $@'
446AC_SUBST(LOLFX_BUILD)
447
448
449dnl Extra libraries we may need
450AC_SUBST(MATH_LIBS)
451AC_SUBST(PAM_LIBS)
452AC_SUBST(UTIL_LIBS)
453
454dnl How to use the Lol Engine inside this tree
455LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
456LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
457LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
458
459AC_SUBST(LOL_CFLAGS)
460AC_SUBST(LOL_LIBS)
461
462
463AC_CONFIG_FILES(
464 [Makefile
465  src/Makefile
466  src/data/Makefile
467  src/data/font/Makefile
468  tutorial/Makefile
469  test/Makefile
470  test/math/Makefile
471  test/sandbox/Makefile
472  test/xolotl/Makefile
473  build/Makefile
474  binaries/Makefile
475  games/Makefile
476  tools/Makefile
477])
478AC_CONFIG_FILES(
479 [games/monsterz/Makefile
480])
481AC_CONFIG_FILES(
482 [games/deushax/Makefile
483  games/deushax/art/Makefile
484  games/deushax/art/test/Makefile
485  games/deushax/gfx/Makefile
486  games/deushax/maps/Makefile
487])
488AC_CONFIG_FILES(
489 [games/mrpigeon/Makefile
490])
491AC_CONFIG_FILES(
492 [games/orbital/Makefile
493])
494AC_CONFIG_FILES(
495 [games/ToukyDemo/Makefile
496])
497AC_CONFIG_FILES(
498 [tools/neercs/Makefile
499])
500
501AC_OUTPUT
502
Note: See TracBrowser for help on using the repository browser.