source: trunk/configure.ac @ 1959

Last change on this file since 1959 was 1959, checked in by sam, 7 years ago

ps3: honour the CELLSDK environment variable if CELL_SDK is not defined.

File size: 15.2 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AM_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25AC_LIBTOOL_WIN32_DLL
26AM_PROG_LIBTOOL
27AC_LIBTOOL_CXX
28
29AC_C_CONST
30AC_C_INLINE
31
32dnl Ensure an error is thrown if pkg-config M4 files are not found.
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34m4_pattern_forbid([^PKG_CHECK_MODULES$])
35m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
36
37dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
38if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
39  export PKG_CONFIG_LIBDIR=/dev/null
40fi
41
42dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
43dnl now otherwise it might be set in an obscure if statement. Same thing for
44dnl PKG_PROG_PKG_CONFIG which needs to be called first.
45AC_EGREP_CPP(yes, foo)
46PKG_PROG_PKG_CONFIG()
47
48AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
49dnl conditional builds
50AC_ARG_ENABLE(debug,
51  [  --enable-debug          build debug versions of the game (default no)])
52AC_ARG_ENABLE(release,
53  [  --enable-release        build final release of the game (default no)])
54AC_ARG_ENABLE(experimental,
55  [  --enable-experimental   experimental build (default no)])
56
57AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
58AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
59AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
60AC_CHECK_HEADERS(sys/wait.h)
61AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
62AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
63AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
64
65if test "${enable_debug}" = "yes"; then
66  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
67  OPT="-O"
68else
69  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
70fi
71
72if test "${enable_release}" = "yes"; then
73  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
74  REL=""
75else
76  REL="-g"
77fi
78
79if test "${enable_experimental}" = "yes"; then
80  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
81fi
82
83dnl No exceptions
84CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
85dnl Optimizations
86CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
87dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
88CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
89
90AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
91AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
92AC_CHECK_LIB(util, forkpty, UTIL_LIBS="${UTIL_LIBS} -lutil")
93
94dnl Are we on the PS3?
95ac_cv_my_have_ps3="no"
96AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
97 [ac_cv_my_have_ps3="yes"
98  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
99  dnl  For PSGL
100  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
101  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
102  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
103  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
104    CELL_SDK="${CELLSDK}"
105  fi
106  if test "x${enable_debug}" = xyes; then
107    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
108  elif test "x${enable_release}" = xyes; then
109    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
110  else
111    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
112  fi
113  dnl  For the runtime Cg compiler
114  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
115  dnl  For the PNG decoder
116  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
117  dnl  For the pad library
118  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
119  dnl  Disable this warning, it's too verbose with vector.h
120  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
121  AC_PATH_PROG(MAKE_FSELF, make_fself, no)],
122 [MAKE_FSELF=no])
123AM_CONDITIONAL(USE_MAKE_FSELF, test "${MAKE_FSELF}" != "no")
124AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
125
126
127dnl  Are we building using MinGW?
128LIBS_save="$LIBS"
129LIBS="$LIBS -mwindows -mwin32"
130AC_MSG_CHECKING(for -mwindows -mwin32)
131AC_TRY_LINK([], [],
132 [AC_MSG_RESULT(yes)
133  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
134  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
135 [AC_MSG_RESULT(no)])
136LIBS="$LIBS_save"
137
138
139dnl  Are we on the Xbox 360?
140dnl  Answer: NO! we don't know how to build for it anyway
141AM_CONDITIONAL(USE_X360, false)
142
143
144dnl Are we on a Direct3D 9 platform?
145#ac_cv_my_have_d3d9="no"
146#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
147#if test "${ac_cv_my_have_d3d9}" != "no"; then
148#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
149#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
150#fi
151#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
152
153
154dnl  Find which version of OpenGL to use
155ac_cv_my_have_gl="no"
156ac_cv_my_stop_looking_for_gl="no"
157
158if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
159  LIBS_save="$LIBS"
160  LIBS="$LIBS -Wl,-framework -Wl,OpenGL"
161  AC_MSG_CHECKING(for -framework OpenGL)
162  AC_TRY_LINK([], [],
163   [AC_MSG_RESULT(yes)
164    GL_LIBS="${GL_LIBS} -framework OpenGL"
165    CXXFLAGS="${CXXFLAGS} -ObjC++"],
166   [AC_MSG_RESULT(no)])
167  LIBS="$LIBS_save"
168fi
169
170dnl  Use the Raspberry Pi libraries?
171if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
172  AC_CHECK_HEADERS(bcm_host.h,
173   [AC_CHECK_LIB(vcos, main,
174     [ac_cv_my_have_gl="yes"
175      ac_cv_my_stop_looking_for_gl="yes"
176      AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
177      dnl  FIXME: -lEGL does not belong here but the configure test fails
178      dnl  when cross-compiling, so we add it manually here.
179      GL_LIBS="${GL_LIBS} -lGLESv2 -lEGL -lvcos -lvchiq_arm -lbcm_host"])])
180fi
181
182dnl  Use the PS3 PSGL?
183if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
184  AC_CHECK_HEADERS(PSGL/psgl.h,
185   [ac_cv_my_have_gl="yes"
186    ac_cv_my_stop_looking_for_gl="yes"])
187fi
188
189if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
190  PKG_CHECK_MODULES(GLES2, glesv2,
191   [ac_cv_my_have_gl="yes"
192    AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
193    GL_CFLAGS="${GL_CFLAGS} ${GLES2_CFLAGS}"
194    GL_LIBS="${GL_LIBS} ${GLES2_LIBS}"],
195   [:])
196fi
197
198if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
199  AC_CHECK_HEADER(GLES2/gl2.h,
200   [ac_cv_my_have_gl="yes"
201    AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
202    AC_CHECK_LIB(GLESv2, glEnable,
203     [GL_LIBS="${GL_LIBS} -lGLESv2"])])
204fi
205
206if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
207  PKG_CHECK_MODULES(GL, gl,
208   [ac_cv_my_have_gl="yes"
209    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available)],
210   [:])
211fi
212
213if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
214  AC_CHECK_LIB(GL, glEnable,
215   [ac_cv_my_have_gl="yes"
216    AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hackish
217    GL_LIBS="-lGL"])
218fi
219
220if test "x${ac_cv_my_stop_looking_for_gl}" = "xno"; then
221  AC_CHECK_HEADER(GL/gl.h,
222   [LIBS_save="$LIBS"
223    LIBS="$LIBS -lopengl32"
224    AC_MSG_CHECKING(for glLoadIdentity in -lopengl32)
225    AC_TRY_LINK([#include <GL/gl.h>],
226     [glLoadIdentity();],
227     [ac_cv_my_have_gl="yes"
228      AC_DEFINE(HAVE_GL_2X, 1, Define to 1 if GL 2.x is available) # FIXME: hack
229      AC_MSG_RESULT(yes)
230      GL_LIBS="-lopengl32"],
231     [AC_MSG_RESULT(no)])
232    LIBS="$LIBS_save"])
233fi
234
235if test "${ac_cv_my_have_gl}" = "no"; then
236  AC_MSG_ERROR([[No OpenGL or OpenGL ES implementation found]])
237fi
238
239
240dnl Use Glew?
241ac_cv_my_have_glew="no"
242PKG_CHECK_MODULES(GLEW, glew,
243 [ac_cv_my_have_glew="yes"
244  GL_CFLAGS="${GLEW_CFLAGS} ${GL_CFLAGS}"
245  GL_LIBS="${GLEW_LIBS} ${GL_LIBS}"],
246 [:])
247AC_CHECK_HEADER(glew.h,
248 [LIBS_save="${LIBS}"
249  LIBS="${LIBS} -lglew32 ${GL_LIBS}"
250  AC_MSG_CHECKING(for glewInit in -lglew32)
251  AC_TRY_LINK(
252   [#include <glew.h>],
253   [glewInit();],
254   [ac_cv_my_have_glew="yes"
255    GL_LIBS="-lglew32 ${GL_LIBS}"
256    AC_MSG_RESULT(yes)],
257   [AC_MSG_RESULT(no)])
258  LIBS="${LIBS_save}"])
259if test "${ac_cv_my_have_glew}" != "no"; then
260  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available)
261  AC_DEFINE(USE_GLEW, 1, Define to 1 to use libglew)
262fi
263AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
264
265dnl Poor man's GL feature detection if all else failed.
266save_LIBS="${LIBS}"
267LIBS="${LIBS} ${GL_LIBS} ${GLES2_LIBS}"
268AC_CHECK_FUNCS(glBegin)
269LIBS="${save_LIBS}"
270
271
272dnl Use SDL? (always required on Linux or Win32)
273ac_cv_my_have_sdl="no"
274ac_cv_my_have_sdl_image="no"
275ac_cv_my_have_sdl_mixer="no"
276dnl
277dnl  First, try the proper pkg-config check
278PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
279PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
280PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
281dnl
282dnl  Then the old sdl-config method
283if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
284  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
285  if test "${SDL_CONFIG}" != "no"; then
286    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
287    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
288    ac_cv_my_have_sdl="yes"
289  fi
290fi
291dnl
292dnl  Maybe all this has failed, try direct inclusion
293save_CPPFLAGS="${CPPFLAGS}"
294save_LIBS="${LIBS}"
295CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
296LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
297AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
298AC_CHECK_HEADERS(SDL_mixer.h SDL/SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
299AC_CHECK_HEADERS(SDL_image.h SDL/SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
300AC_CHECK_LIB(SDL, main,
301 [SDL_LIBS="${SDL_LIBS} -lSDL"],
302 [ac_cv_my_have_sdl="no"])
303AC_CHECK_LIB(SDLmain, main,
304 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
305AC_CHECK_LIB(SDL_mixer, main,
306 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
307 [ac_cv_my_have_sdl_mixer="no"])
308AC_CHECK_LIB(SDL_image, main,
309 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
310 [ac_cv_my_have_sdl_image="no"])
311SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
312SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
313CPPFLAGS="${save_CPPFLAGS}"
314LIBS="${save_LIBS}"
315if test "${ac_cv_my_have_sdl}" = "no"; then
316  AC_MSG_WARN([SDL not found])
317else
318  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
319fi
320if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
321  AC_MSG_WARN([SDL_mixer not found])
322else
323  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
324fi
325if test "${ac_cv_my_have_sdl_image}" = "no"; then
326  AC_MSG_WARN([SDL_image not found])
327else
328  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
329fi
330AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
331AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
332AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
333
334
335dnl  Use Flex's FlexLexer.h or ours?
336ac_cv_my_have_flexlexer_h="no"
337AC_LANG_PUSH(C++)
338AC_CHECK_HEADERS(FlexLexer.h, [ac_cv_my_have_flexlexer_h="yes"])
339AC_LANG_POP(C++)
340if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
341  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/contrib/flex-2.5.35/include"
342fi
343
344
345dnl  Use NativeClient?
346ac_cv_my_have_nacl="no"
347AC_LANG_PUSH(C++)
348AC_CHECK_HEADERS(ppapi/cpp/instance.h,
349 [ac_cv_my_have_nacl="yes"
350  dnl  Disable this warning, it's too verbose with vector.h
351  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
352AC_LANG_POP(C++)
353AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
354
355
356dnl  Use Android? FIXME: super hacks!
357ac_cv_my_have_android="no"
358AC_CHECK_LIB(log, __android_log_vprint,
359 [ac_cv_my_have_android="yes"
360  LOL_LIBS="${LOL_LIBS} -llog -module"])
361AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
362
363
364dnl  Use EGL?
365ac_cv_my_have_egl="no"
366PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
367if test "${ac_cv_my_have_egl}" != "no"; then
368  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
369  EGL_LIBS="${EGL_LIBS} -lX11"
370fi
371AC_CHECK_LIB(EGL, main,
372 [ac_cv_my_have_egl="yes"
373  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
374  EGL_LIBS="-lEGL"])
375dnl  Raspberry Pi is different, check for it with extra libs; also we
376dnl  look for a different function to bypass autoconf caching
377AC_CHECK_LIB(EGL, eglGetDisplay,
378 [ac_cv_my_have_egl="yes"
379  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
380  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
381 [:],
382 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
383AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
384
385
386dnl Use libpng? (replacement for SDL_image)
387ac_cv_my_have_libpng="no"
388PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
389if test "${ac_cv_my_have_libpng}" != "no"; then
390  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
391fi
392AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
393
394
395dnl Use Windows GDI+?
396ac_cv_my_have_gdiplus="no"
397AC_LANG_PUSH(C++)
398AC_CHECK_HEADERS(gdiplus.h,
399 [ac_cv_my_have_gdiplus="yes"
400  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
401 [ac_cv_my_have_gdiplus="no"],
402 [#include <algorithm>
403  using std::min;
404  using std::max;
405  #include <windows.h>])
406AC_LANG_POP(C++)
407if test "${ac_cv_my_have_gdiplus}" != "no"; then
408  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
409fi
410AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
411
412
413dnl Use libcaca? (required for font generation)
414ac_cv_my_have_caca="no"
415PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
416if test "${ac_cv_my_have_caca}" != "no"; then
417  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
418fi
419AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
420
421
422dnl Use libpipi? (required for video recording)
423ac_cv_my_have_pipi="no"
424PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
425if test "${ac_cv_my_have_pipi}" != "no"; then
426  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
427fi
428AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
429
430
431dnl Use GTK+? (required for the deushax editor)
432ac_cv_my_have_gtkgl="no"
433PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
434PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
435if test "${ac_cv_my_have_gtkgl}" != "no"; then
436  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
437fi
438AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
439
440
441dnl  Can we build neercs?
442AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no" -a "${ac_cv_header_glob_h}" = "yes")
443
444
445dnl Extra libraries we may need
446AC_SUBST(MATH_LIBS)
447AC_SUBST(PAM_LIBS)
448AC_SUBST(UTIL_LIBS)
449
450dnl How to use the Lol Engine inside this tree
451LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
452LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
453LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
454
455AC_SUBST(LOL_CFLAGS)
456AC_SUBST(LOL_LIBS)
457
458
459AC_CONFIG_FILES(
460 [Makefile
461  src/Makefile
462  src/data/Makefile
463  src/data/font/Makefile
464  tutorial/Makefile
465  test/Makefile
466  test/math/Makefile
467  test/sandbox/Makefile
468  test/xolotl/Makefile
469  build/Makefile
470  binaries/Makefile
471  people/Makefile
472  games/Makefile
473  tools/Makefile
474  tools/vslol/Makefile
475])
476AC_CONFIG_FILES(
477 [games/monsterz/Makefile
478])
479AC_CONFIG_FILES(
480 [games/deushax/Makefile
481  games/deushax/art/Makefile
482  games/deushax/art/test/Makefile
483  games/deushax/gfx/Makefile
484  games/deushax/maps/Makefile
485])
486AC_CONFIG_FILES(
487 [games/mrpigeon/Makefile
488])
489AC_CONFIG_FILES(
490 [games/orbital/Makefile
491])
492AC_CONFIG_FILES(
493 [tools/neercs/Makefile
494])
495AC_CONFIG_FILES(
496 [people/jnat/Makefile
497  people/peeweek/Makefile
498  people/touky/Makefile
499])
500
501AC_OUTPUT
502
Note: See TracBrowser for help on using the repository browser.