source: trunk/configure.ac @ 2167

Last change on this file since 2167 was 2167, checked in by jylam, 7 years ago
  • Doxygen doc / manpages
File size: 13.8 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AM_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25AC_LIBTOOL_WIN32_DLL
26AM_PROG_LIBTOOL
27AC_LIBTOOL_CXX
28
29AC_C_CONST
30AC_C_INLINE
31
32dnl Ensure an error is thrown if pkg-config M4 files are not found.
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34m4_pattern_forbid([^PKG_CHECK_MODULES$])
35m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
36
37dnl  Same for Lol Engine M4 files.
38m4_pattern_forbid([^LOL_])
39
40
41dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
42if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
43  export PKG_CONFIG_LIBDIR=/dev/null
44fi
45
46dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
47dnl now otherwise it might be set in an obscure if statement. Same thing for
48dnl PKG_PROG_PKG_CONFIG which needs to be called first.
49AC_EGREP_CPP(yes, foo)
50PKG_PROG_PKG_CONFIG()
51
52
53dnl  Check for a working implementation of sed
54AC_PROG_SED
55AC_MSG_CHECKING(for a sed that understands \t)
56if test "$(echo 'x\x' | "${SED}" 's/.*@<:@^x\t@:>@//')" != x; then
57  AC_MSG_RESULT(no)
58  AC_MSG_ERROR([[consider installing GNU sed]])
59else
60  AC_MSG_RESULT(yes)
61fi
62
63
64AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
65dnl conditional builds
66AC_ARG_ENABLE(debug,
67  [  --enable-debug          build debug versions of the game (default no)])
68AC_ARG_ENABLE(release,
69  [  --enable-release        build final release of the game (default no)])
70AC_ARG_ENABLE(experimental,
71  [  --enable-experimental   experimental build (default no)])
72AC_ARG_ENABLE(doc,
73  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
74
75AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
76AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
77AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
78AC_CHECK_HEADERS(sys/wait.h)
79AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
80AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
81AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
82
83if test "${enable_debug}" = "yes"; then
84  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
85  OPT="-O"
86else
87  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
88fi
89
90if test "${enable_release}" = "yes"; then
91  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
92  REL=""
93else
94  REL="-g"
95fi
96
97if test "${enable_experimental}" = "yes"; then
98  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
99fi
100
101# Build documentation?
102DOXYGEN="no"
103LATEX="no"
104if test "${enable_doc}" != "no"; then
105  AC_PATH_PROG(DOXYGEN, doxygen, no)
106  if test "${DOXYGEN}" != "no"; then
107    # Build LaTeX documentation?
108    AC_PATH_PROG(LATEX, pdflatex, no)
109    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
110    AC_PATH_PROG(DVIPS, dvips, no)
111    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
112      LATEX="no"
113    fi
114    if test "${LATEX}" != "no"; then
115      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
116      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
117        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
118          AC_MSG_RESULT(yes)
119        else
120          LATEX="no"
121          AC_MSG_RESULT(no)
122        fi
123      else
124        LATEX="no"
125        AC_MSG_RESULT(no)
126      fi
127    fi
128  fi
129fi
130AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
131AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
132
133dnl No exceptions
134CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
135dnl Optimizations
136CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
137dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
138CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
139
140AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
141AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
142
143AC_CHECK_LIB(util, forkpty,
144 [UTIL_LIBS="${UTIL_LIBS} -lutil"
145  dnl  Override future forkpty detection
146  ac_cv_func_forkpty="yes"])
147AC_CHECK_FUNCS(forkpty)
148
149dnl Are we on the PS3?
150ac_cv_my_have_ps3="no"
151AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
152 [ac_cv_my_have_ps3="yes"
153  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
154  dnl  For PSGL
155  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
156  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
157  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
158  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
159    CELL_SDK="${CELLSDK}"
160  fi
161  if test "x${enable_debug}" = xyes; then
162    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
163  elif test "x${enable_release}" = xyes; then
164    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
165  else
166    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
167  fi
168  dnl  For the runtime Cg compiler
169  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
170  dnl  For the PNG decoder
171  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
172  dnl  For the pad library
173  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
174  dnl  Disable this warning, it's too verbose with vector.h
175  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
176  AC_PATH_PROG(MAKE_FSELF, make_fself, no)
177  if test "${MAKE_FSELF}" = "no"; then
178    AC_MSG_ERROR([[Building for PS3 but make_fself not found]])
179  fi],
180 [MAKE_FSELF=no])
181AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
182
183
184dnl  Are we building using MinGW?
185LIBS_save="$LIBS"
186LIBS="$LIBS -mwindows -mwin32"
187AC_MSG_CHECKING(for -mwindows -mwin32)
188AC_TRY_LINK([], [],
189 [AC_MSG_RESULT(yes)
190  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
191  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
192 [AC_MSG_RESULT(no)])
193LIBS="$LIBS_save"
194
195
196dnl  Are we on the Xbox 360?
197dnl  Answer: NO! we don't know how to build for it anyway
198AM_CONDITIONAL(USE_X360, false)
199
200
201dnl Are we on a Direct3D 9 platform?
202#ac_cv_my_have_d3d9="no"
203#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
204#if test "${ac_cv_my_have_d3d9}" != "no"; then
205#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
206#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
207#fi
208#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
209
210LOL_CHECK_OPENGL
211
212
213dnl Use SDL? (always required on Linux or Win32)
214ac_cv_my_have_sdl="no"
215ac_cv_my_have_sdl_image="no"
216ac_cv_my_have_sdl_mixer="no"
217dnl
218dnl  First, try the proper pkg-config check
219PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
220PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
221PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
222dnl
223dnl  Then the old sdl-config method
224if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
225  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
226  if test "${SDL_CONFIG}" != "no"; then
227    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
228    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
229    ac_cv_my_have_sdl="yes"
230  fi
231fi
232dnl
233dnl  Maybe all this has failed, try direct inclusion
234save_CPPFLAGS="${CPPFLAGS}"
235save_LIBS="${LIBS}"
236CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
237LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
238AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
239AC_CHECK_HEADERS(SDL_mixer.h SDL/SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
240AC_CHECK_HEADERS(SDL_image.h SDL/SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
241AC_CHECK_LIB(SDL, main,
242 [SDL_LIBS="${SDL_LIBS} -lSDL"],
243 [ac_cv_my_have_sdl="no"])
244AC_CHECK_LIB(SDLmain, main,
245 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
246AC_CHECK_LIB(SDL_mixer, main,
247 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
248 [ac_cv_my_have_sdl_mixer="no"])
249AC_CHECK_LIB(SDL_image, main,
250 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
251 [ac_cv_my_have_sdl_image="no"])
252SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
253SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
254CPPFLAGS="${save_CPPFLAGS}"
255LIBS="${save_LIBS}"
256if test "${ac_cv_my_have_sdl}" = "no"; then
257  AC_MSG_WARN([SDL not found])
258else
259  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
260fi
261if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
262  AC_MSG_WARN([SDL_mixer not found])
263else
264  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
265fi
266if test "${ac_cv_my_have_sdl_image}" = "no"; then
267  AC_MSG_WARN([SDL_image not found])
268else
269  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
270fi
271AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
272AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
273AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
274
275
276dnl  Use Flex's FlexLexer.h or ours?
277ac_cv_my_have_flexlexer_h="no"
278AC_LANG_PUSH(C++)
279AC_CHECK_HEADERS(FlexLexer.h,
280 dnl  Ensure that FlexLexer::yleng is of type int, and not size_t like
281 dnl  on recent Apple systems. It would break all our existing code.
282 [AC_MSG_CHECKING(for FlexLexer.h validity)
283  AC_COMPILE_IFELSE(
284   [AC_LANG_PROGRAM([#include <FlexLexer.h>
285      class Foo : public FlexLexer
286      {
287          Foo() { int &test = yyleng; }
288      }],
289     [])],
290   [AC_MSG_RESULT(yes)
291    ac_cv_my_have_flexlexer_h="yes"],
292   [AC_MSG_RESULT(no)])])
293AC_LANG_POP(C++)
294if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
295  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/external/flex-2.5.35/include"
296fi
297
298
299dnl  Use NativeClient?
300ac_cv_my_have_nacl="no"
301AC_LANG_PUSH(C++)
302AC_CHECK_HEADERS(ppapi/cpp/instance.h,
303 [ac_cv_my_have_nacl="yes"
304  dnl  Disable this warning, it's too verbose with vector.h
305  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
306AC_LANG_POP(C++)
307AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
308
309
310dnl  Use Android? FIXME: super hacks!
311ac_cv_my_have_android="no"
312AC_CHECK_LIB(log, __android_log_vprint,
313 [ac_cv_my_have_android="yes"
314  LOL_LIBS="${LOL_LIBS} -llog -module"])
315AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
316
317
318dnl  Use EGL?
319ac_cv_my_have_egl="no"
320PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
321if test "${ac_cv_my_have_egl}" != "no"; then
322  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
323  EGL_LIBS="${EGL_LIBS} -lX11"
324fi
325AC_CHECK_LIB(EGL, main,
326 [ac_cv_my_have_egl="yes"
327  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
328  EGL_LIBS="-lEGL"])
329dnl  Raspberry Pi is different, check for it with extra libs; also we
330dnl  look for a different function to bypass autoconf caching
331AC_CHECK_LIB(EGL, eglGetDisplay,
332 [ac_cv_my_have_egl="yes"
333  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
334  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
335 [:],
336 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
337AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
338
339
340dnl Use libpng? (replacement for SDL_image)
341ac_cv_my_have_libpng="no"
342PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
343if test "${ac_cv_my_have_libpng}" != "no"; then
344  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
345fi
346AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
347
348
349dnl Use Windows GDI+?
350ac_cv_my_have_gdiplus="no"
351AC_LANG_PUSH(C++)
352AC_CHECK_HEADERS(gdiplus.h,
353 [ac_cv_my_have_gdiplus="yes"
354  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
355 [ac_cv_my_have_gdiplus="no"],
356 [#include <algorithm>
357  using std::min;
358  using std::max;
359  #include <windows.h>])
360AC_LANG_POP(C++)
361if test "${ac_cv_my_have_gdiplus}" != "no"; then
362  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
363fi
364AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
365
366
367dnl Use libcaca? (required for font generation)
368ac_cv_my_have_caca="no"
369PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
370if test "${ac_cv_my_have_caca}" != "no"; then
371  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
372fi
373AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
374
375
376dnl Use libpipi? (required for video recording)
377ac_cv_my_have_pipi="no"
378PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
379if test "${ac_cv_my_have_pipi}" != "no"; then
380  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
381  LOL_CFLAGS="${LOL_CFLAGS} ${PIPI_CFLAGS}"
382  LOL_LIBS="${LOL_LIBS} ${PIPI_LIBS}"
383fi
384AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
385
386
387dnl Use GTK+? (required for the deushax editor)
388ac_cv_my_have_gtkgl="no"
389PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
390PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
391if test "${ac_cv_my_have_gtkgl}" != "no"; then
392  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
393fi
394AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
395
396
397dnl  Can we build neercs?
398AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no")
399
400
401dnl Extra libraries we may need
402AC_SUBST(MATH_LIBS)
403AC_SUBST(PAM_LIBS)
404AC_SUBST(UTIL_LIBS)
405
406dnl How to use the Lol Engine inside this tree
407LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
408LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
409LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
410
411AC_SUBST(LOL_CFLAGS)
412AC_SUBST(LOL_LIBS)
413
414
415AC_CONFIG_FILES(
416 [Makefile
417  src/Makefile
418  src/data/Makefile
419  src/data/font/Makefile
420  tutorial/Makefile
421  test/Makefile
422  test/math/Makefile
423  test/sandbox/Makefile
424  test/xolotl/Makefile
425  build/Makefile
426  binaries/Makefile
427  people/Makefile
428  games/Makefile
429  tools/Makefile
430  tools/vimlol/Makefile
431  tools/vslol/Makefile
432  doc/Makefile
433  doc/doxygen.cfg
434])
435AC_CONFIG_FILES(
436 [games/monsterz/Makefile
437])
438AC_CONFIG_FILES(
439 [games/deushax/Makefile
440  games/deushax/art/Makefile
441  games/deushax/art/test/Makefile
442  games/deushax/gfx/Makefile
443  games/deushax/maps/Makefile
444])
445AC_CONFIG_FILES(
446 [games/mrpigeon/Makefile
447])
448AC_CONFIG_FILES(
449 [games/orbital/Makefile
450])
451AC_CONFIG_FILES(
452 [tools/neercs/Makefile
453])
454AC_CONFIG_FILES(
455 [people/jnat/Makefile
456  people/jnat/TestProject/Makefile
457  people/peeweek/Makefile
458  people/touky/Makefile
459  people/jylam/Makefile
460  people/jylam/chat/Makefile
461])
462
463AC_OUTPUT
464
Note: See TracBrowser for help on using the repository browser.