source: trunk/configure.ac @ 2175

Last change on this file since 2175 was 2175, checked in by jylam, 7 years ago
  • Doxygen: add src/lol/ subdirectories
File size: 13.9 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AM_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25AC_LIBTOOL_WIN32_DLL
26AM_PROG_LIBTOOL
27AC_LIBTOOL_CXX
28
29AC_C_CONST
30AC_C_INLINE
31
32dnl Ensure an error is thrown if pkg-config M4 files are not found.
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34m4_pattern_forbid([^PKG_CHECK_MODULES$])
35m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
36
37dnl  Same for Lol Engine M4 files.
38m4_pattern_forbid([^LOL_])
39
40
41dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
42if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
43  export PKG_CONFIG_LIBDIR=/dev/null
44fi
45
46dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
47dnl now otherwise it might be set in an obscure if statement. Same thing for
48dnl PKG_PROG_PKG_CONFIG which needs to be called first.
49AC_EGREP_CPP(yes, foo)
50PKG_PROG_PKG_CONFIG()
51
52
53dnl  Check for a working implementation of sed
54AC_PROG_SED
55AC_MSG_CHECKING(for a sed that understands \t)
56if test "$(echo 'x\x' | "${SED}" 's/.*@<:@^x\t@:>@//')" != x; then
57  AC_MSG_RESULT(no)
58  AC_MSG_ERROR([[consider installing GNU sed]])
59else
60  AC_MSG_RESULT(yes)
61fi
62
63
64AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
65dnl conditional builds
66AC_ARG_ENABLE(debug,
67  [  --enable-debug          build debug versions of the game (default no)])
68AC_ARG_ENABLE(release,
69  [  --enable-release        build final release of the game (default no)])
70AC_ARG_ENABLE(experimental,
71  [  --enable-experimental   experimental build (default no)])
72AC_ARG_ENABLE(doc,
73  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
74
75AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
76AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h)
77AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
78AC_CHECK_HEADERS(sys/wait.h)
79AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
80AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
81AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
82
83if test "${enable_debug}" = "yes"; then
84  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
85  OPT="-O"
86else
87  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
88fi
89
90if test "${enable_release}" = "yes"; then
91  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
92  REL=""
93else
94  REL="-g"
95fi
96
97if test "${enable_experimental}" = "yes"; then
98  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
99fi
100
101# Build documentation?
102DOXYGEN="no"
103LATEX="no"
104if test "${enable_doc}" != "no"; then
105  AC_PATH_PROG(DOXYGEN, doxygen, no)
106  if test "${DOXYGEN}" != "no"; then
107    # Build LaTeX documentation?
108    AC_PATH_PROG(LATEX, pdflatex, no)
109    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
110    AC_PATH_PROG(DVIPS, dvips, no)
111    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
112      LATEX="no"
113    fi
114    if test "${LATEX}" != "no"; then
115      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
116      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
117        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
118          AC_MSG_RESULT(yes)
119        else
120          LATEX="no"
121          AC_MSG_RESULT(no)
122        fi
123      else
124        LATEX="no"
125        AC_MSG_RESULT(no)
126      fi
127    fi
128    AC_PATH_PROG(DOT, dot, no)
129    if test "${DOT}" != "no"; then
130      USE_DOT="YES"
131    else
132      USE_DOT="NO"
133    fi
134  fi
135fi
136AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
137AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
138AM_CONDITIONAL(USE_DOT, test "${DOT}" != "no")
139
140dnl No exceptions
141CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
142dnl Optimizations
143CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
144dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
145CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
146
147AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
148AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
149
150AC_CHECK_LIB(util, forkpty,
151 [UTIL_LIBS="${UTIL_LIBS} -lutil"
152  dnl  Override future forkpty detection
153  ac_cv_func_forkpty="yes"])
154AC_CHECK_FUNCS(forkpty)
155
156dnl Are we on the PS3?
157ac_cv_my_have_ps3="no"
158AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
159 [ac_cv_my_have_ps3="yes"
160  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
161  dnl  For PSGL
162  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
163  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
164  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
165  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
166    CELL_SDK="${CELLSDK}"
167  fi
168  if test "x${enable_debug}" = xyes; then
169    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
170  elif test "x${enable_release}" = xyes; then
171    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
172  else
173    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
174  fi
175  dnl  For the runtime Cg compiler
176  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
177  dnl  For the PNG decoder
178  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
179  dnl  For the pad library
180  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
181  dnl  Disable this warning, it's too verbose with vector.h
182  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
183  AC_PATH_PROG(MAKE_FSELF, make_fself, no)
184  if test "${MAKE_FSELF}" = "no"; then
185    AC_MSG_ERROR([[Building for PS3 but make_fself not found]])
186  fi],
187 [MAKE_FSELF=no])
188AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
189
190
191dnl  Are we building using MinGW?
192LIBS_save="$LIBS"
193LIBS="$LIBS -mwindows -mwin32"
194AC_MSG_CHECKING(for -mwindows -mwin32)
195AC_TRY_LINK([], [],
196 [AC_MSG_RESULT(yes)
197  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
198  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
199 [AC_MSG_RESULT(no)])
200LIBS="$LIBS_save"
201
202
203dnl  Are we on the Xbox 360?
204dnl  Answer: NO! we don't know how to build for it anyway
205AM_CONDITIONAL(USE_X360, false)
206
207
208dnl Are we on a Direct3D 9 platform?
209#ac_cv_my_have_d3d9="no"
210#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
211#if test "${ac_cv_my_have_d3d9}" != "no"; then
212#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
213#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
214#fi
215#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
216
217LOL_CHECK_OPENGL
218
219
220dnl Use SDL? (always required on Linux or Win32)
221ac_cv_my_have_sdl="no"
222ac_cv_my_have_sdl_image="no"
223ac_cv_my_have_sdl_mixer="no"
224dnl
225dnl  First, try the proper pkg-config check
226PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
227PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
228PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
229dnl
230dnl  Then the old sdl-config method
231if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
232  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
233  if test "${SDL_CONFIG}" != "no"; then
234    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
235    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
236    ac_cv_my_have_sdl="yes"
237  fi
238fi
239dnl
240dnl  Maybe all this has failed, try direct inclusion
241save_CPPFLAGS="${CPPFLAGS}"
242save_LIBS="${LIBS}"
243CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
244LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
245AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
246AC_CHECK_HEADERS(SDL_mixer.h SDL/SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
247AC_CHECK_HEADERS(SDL_image.h SDL/SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
248AC_CHECK_LIB(SDL, main,
249 [SDL_LIBS="${SDL_LIBS} -lSDL"],
250 [ac_cv_my_have_sdl="no"])
251AC_CHECK_LIB(SDLmain, main,
252 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
253AC_CHECK_LIB(SDL_mixer, main,
254 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
255 [ac_cv_my_have_sdl_mixer="no"])
256AC_CHECK_LIB(SDL_image, main,
257 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
258 [ac_cv_my_have_sdl_image="no"])
259SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
260SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
261CPPFLAGS="${save_CPPFLAGS}"
262LIBS="${save_LIBS}"
263if test "${ac_cv_my_have_sdl}" = "no"; then
264  AC_MSG_WARN([SDL not found])
265else
266  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
267fi
268if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
269  AC_MSG_WARN([SDL_mixer not found])
270else
271  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
272fi
273if test "${ac_cv_my_have_sdl_image}" = "no"; then
274  AC_MSG_WARN([SDL_image not found])
275else
276  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
277fi
278AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
279AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
280AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
281
282
283dnl  Use Flex's FlexLexer.h or ours?
284ac_cv_my_have_flexlexer_h="no"
285AC_LANG_PUSH(C++)
286AC_CHECK_HEADERS(FlexLexer.h,
287 dnl  Ensure that FlexLexer::yleng is of type int, and not size_t like
288 dnl  on recent Apple systems. It would break all our existing code.
289 [AC_MSG_CHECKING(for FlexLexer.h validity)
290  AC_COMPILE_IFELSE(
291   [AC_LANG_PROGRAM([#include <FlexLexer.h>
292      class Foo : public FlexLexer
293      {
294          Foo() { int &test = yyleng; }
295      }],
296     [])],
297   [AC_MSG_RESULT(yes)
298    ac_cv_my_have_flexlexer_h="yes"],
299   [AC_MSG_RESULT(no)])])
300AC_LANG_POP(C++)
301if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
302  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/external/flex-2.5.35/include"
303fi
304
305
306dnl  Use NativeClient?
307ac_cv_my_have_nacl="no"
308AC_LANG_PUSH(C++)
309AC_CHECK_HEADERS(ppapi/cpp/instance.h,
310 [ac_cv_my_have_nacl="yes"
311  dnl  Disable this warning, it's too verbose with vector.h
312  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
313AC_LANG_POP(C++)
314AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
315
316
317dnl  Use Android? FIXME: super hacks!
318ac_cv_my_have_android="no"
319AC_CHECK_LIB(log, __android_log_vprint,
320 [ac_cv_my_have_android="yes"
321  LOL_LIBS="${LOL_LIBS} -llog -module"])
322AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
323
324
325dnl  Use EGL?
326ac_cv_my_have_egl="no"
327PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
328if test "${ac_cv_my_have_egl}" != "no"; then
329  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
330  EGL_LIBS="${EGL_LIBS} -lX11"
331fi
332AC_CHECK_LIB(EGL, main,
333 [ac_cv_my_have_egl="yes"
334  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
335  EGL_LIBS="-lEGL"])
336dnl  Raspberry Pi is different, check for it with extra libs; also we
337dnl  look for a different function to bypass autoconf caching
338AC_CHECK_LIB(EGL, eglGetDisplay,
339 [ac_cv_my_have_egl="yes"
340  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
341  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
342 [:],
343 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
344AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
345
346
347dnl Use libpng? (replacement for SDL_image)
348ac_cv_my_have_libpng="no"
349PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
350if test "${ac_cv_my_have_libpng}" != "no"; then
351  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
352fi
353AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
354
355
356dnl Use Windows GDI+?
357ac_cv_my_have_gdiplus="no"
358AC_LANG_PUSH(C++)
359AC_CHECK_HEADERS(gdiplus.h,
360 [ac_cv_my_have_gdiplus="yes"
361  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
362 [ac_cv_my_have_gdiplus="no"],
363 [#include <algorithm>
364  using std::min;
365  using std::max;
366  #include <windows.h>])
367AC_LANG_POP(C++)
368if test "${ac_cv_my_have_gdiplus}" != "no"; then
369  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
370fi
371AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
372
373
374dnl Use libcaca? (required for font generation)
375ac_cv_my_have_caca="no"
376PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
377if test "${ac_cv_my_have_caca}" != "no"; then
378  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
379fi
380AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
381
382
383dnl Use libpipi? (required for video recording)
384ac_cv_my_have_pipi="no"
385PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
386if test "${ac_cv_my_have_pipi}" != "no"; then
387  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
388  LOL_CFLAGS="${LOL_CFLAGS} ${PIPI_CFLAGS}"
389  LOL_LIBS="${LOL_LIBS} ${PIPI_LIBS}"
390fi
391AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
392
393
394dnl Use GTK+? (required for the deushax editor)
395ac_cv_my_have_gtkgl="no"
396PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
397PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
398if test "${ac_cv_my_have_gtkgl}" != "no"; then
399  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
400fi
401AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
402
403
404dnl  Can we build neercs?
405AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no")
406
407
408dnl Extra libraries we may need
409AC_SUBST(MATH_LIBS)
410AC_SUBST(PAM_LIBS)
411AC_SUBST(UTIL_LIBS)
412
413dnl How to use the Lol Engine inside this tree
414LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src"
415LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
416LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
417
418AC_SUBST(LOL_CFLAGS)
419AC_SUBST(LOL_LIBS)
420
421AC_SUBST(USE_DOT)
422
423AC_CONFIG_FILES(
424 [Makefile
425  src/Makefile
426  src/data/Makefile
427  src/data/font/Makefile
428  tutorial/Makefile
429  test/Makefile
430  test/math/Makefile
431  test/sandbox/Makefile
432  test/xolotl/Makefile
433  build/Makefile
434  binaries/Makefile
435  people/Makefile
436  games/Makefile
437  tools/Makefile
438  tools/vimlol/Makefile
439  tools/vslol/Makefile
440  doc/Makefile
441  doc/doxygen.cfg
442])
443AC_CONFIG_FILES(
444 [games/monsterz/Makefile
445])
446AC_CONFIG_FILES(
447 [games/deushax/Makefile
448  games/deushax/art/Makefile
449  games/deushax/art/test/Makefile
450  games/deushax/gfx/Makefile
451  games/deushax/maps/Makefile
452])
453AC_CONFIG_FILES(
454 [games/mrpigeon/Makefile
455])
456AC_CONFIG_FILES(
457 [games/orbital/Makefile
458])
459AC_CONFIG_FILES(
460 [tools/neercs/Makefile
461])
462AC_CONFIG_FILES(
463 [people/jnat/Makefile
464  people/jnat/TestProject/Makefile
465  people/peeweek/Makefile
466  people/touky/Makefile
467  people/jylam/Makefile
468  people/jylam/chat/Makefile
469])
470
471AC_OUTPUT
472
Note: See TracBrowser for help on using the repository browser.