source: trunk/configure.ac @ 2263

Last change on this file since 2263 was 2263, checked in by sam, 7 years ago

build: check for getcwd() and _getcwd() and configure time.

File size: 14.1 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AM_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25AC_LIBTOOL_WIN32_DLL
26AM_PROG_LIBTOOL
27AC_LIBTOOL_CXX
28
29AC_C_CONST
30AC_C_INLINE
31
32dnl Ensure an error is thrown if pkg-config M4 files are not found.
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34m4_pattern_forbid([^PKG_CHECK_MODULES$])
35m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
36
37dnl  Same for Lol Engine M4 files.
38m4_pattern_forbid([^LOL_])
39
40
41dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
42if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
43  export PKG_CONFIG_LIBDIR=/dev/null
44fi
45
46dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
47dnl now otherwise it might be set in an obscure if statement. Same thing for
48dnl PKG_PROG_PKG_CONFIG which needs to be called first.
49AC_EGREP_CPP(yes, foo)
50PKG_PROG_PKG_CONFIG()
51
52
53dnl  Check for a working implementation of sed
54AC_PROG_SED
55AC_MSG_CHECKING(for a sed that understands \t)
56if test "$(echo 'x\x' | "${SED}" 's/.*@<:@^x\t@:>@//')" != x; then
57  AC_MSG_RESULT(no)
58  AC_MSG_ERROR([[consider installing GNU sed]])
59else
60  AC_MSG_RESULT(yes)
61fi
62
63
64AM_CONDITIONAL(USE_GLEW, test "${ac_cv_my_have_glew}" != "no")
65dnl conditional builds
66AC_ARG_ENABLE(debug,
67  [  --enable-debug          build debug versions of the game (default no)])
68AC_ARG_ENABLE(release,
69  [  --enable-release        build final release of the game (default no)])
70AC_ARG_ENABLE(experimental,
71  [  --enable-experimental   experimental build (default no)])
72AC_ARG_ENABLE(doc,
73  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
74
75AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
76AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h unistd.h)
77AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
78AC_CHECK_HEADERS(sys/wait.h)
79AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
80AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
81AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
82
83AC_CHECK_FUNCS(getcwd _getcwd)
84
85if test "${enable_debug}" = "yes"; then
86  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
87  OPT="-O"
88else
89  OPT="-O3 -ffast-math -fno-strength-reduce -fomit-frame-pointer"
90fi
91
92if test "${enable_release}" = "yes"; then
93  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
94  REL=""
95else
96  REL="-g"
97fi
98
99if test "${enable_experimental}" = "yes"; then
100  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
101fi
102
103# Build documentation?
104DOXYGEN="no"
105LATEX="no"
106if test "${enable_doc}" != "no"; then
107  AC_PATH_PROG(DOXYGEN, doxygen, no)
108  if test "${DOXYGEN}" != "no"; then
109    # Build LaTeX documentation?
110    AC_PATH_PROG(LATEX, pdflatex, no)
111    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
112    AC_PATH_PROG(DVIPS, dvips, no)
113    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
114      LATEX="no"
115    fi
116    if test "${LATEX}" != "no"; then
117      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
118      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
119        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
120          AC_MSG_RESULT(yes)
121        else
122          LATEX="no"
123          AC_MSG_RESULT(no)
124        fi
125      else
126        LATEX="no"
127        AC_MSG_RESULT(no)
128      fi
129    fi
130    AC_PATH_PROG(DOT, dot, no)
131    if test "${DOT}" != "no"; then
132      USE_DOT="YES"
133    else
134      USE_DOT="NO"
135    fi
136  fi
137fi
138AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
139AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
140AM_CONDITIONAL(USE_DOT, test "${DOT}" != "no")
141
142dnl No exceptions
143CXXFLAGS="${CXXFLAGS} -fno-exceptions -fno-rtti"
144dnl Optimizations
145CXXFLAGS="${CXXFLAGS} ${REL} ${OPT}"
146dnl Code qui fait des warnings == code de porc == deux baffes dans ta gueule
147CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
148
149AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
150AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
151
152AC_CHECK_LIB(util, forkpty,
153 [UTIL_LIBS="${UTIL_LIBS} -lutil"
154  dnl  Override future forkpty detection
155  ac_cv_func_forkpty="yes"])
156AC_CHECK_FUNCS(forkpty)
157
158dnl Are we on the PS3?
159ac_cv_my_have_ps3="no"
160AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
161 [ac_cv_my_have_ps3="yes"
162  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
163  dnl  For PSGL
164  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
165  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
166  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
167  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
168    CELL_SDK="${CELLSDK}"
169  fi
170  if test "x${enable_debug}" = xyes; then
171    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
172  elif test "x${enable_release}" = xyes; then
173    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
174  else
175    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
176  fi
177  dnl  For the runtime Cg compiler
178  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
179  dnl  For the PNG decoder
180  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
181  dnl  For the pad library
182  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
183  dnl  Disable this warning, it's too verbose with vector.h
184  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"
185  AC_PATH_PROG(MAKE_FSELF, make_fself, no)
186  if test "${MAKE_FSELF}" = "no"; then
187    AC_MSG_ERROR([[Building for PS3 but make_fself not found]])
188  fi],
189 [MAKE_FSELF=no])
190AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
191
192
193dnl  Are we building using MinGW?
194LIBS_save="$LIBS"
195LIBS="$LIBS -mwindows -mwin32"
196AC_MSG_CHECKING(for -mwindows -mwin32)
197AC_TRY_LINK([], [],
198 [AC_MSG_RESULT(yes)
199  CXXFLAGS="${CXXFLAGS} -mwindows -mwin32"
200  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"],
201 [AC_MSG_RESULT(no)])
202LIBS="$LIBS_save"
203
204
205dnl  Are we on the Xbox 360?
206dnl  Answer: NO! we don't know how to build for it anyway
207AM_CONDITIONAL(USE_X360, false)
208
209
210dnl Are we on a Direct3D 9 platform?
211#ac_cv_my_have_d3d9="no"
212#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
213#if test "${ac_cv_my_have_d3d9}" != "no"; then
214#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
215#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
216#fi
217#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
218
219LOL_CHECK_OPENGL
220
221
222dnl Use SDL? (always required on Linux or Win32)
223ac_cv_my_have_sdl="no"
224ac_cv_my_have_sdl_image="no"
225ac_cv_my_have_sdl_mixer="no"
226dnl
227dnl  First, try the proper pkg-config check
228PKG_CHECK_MODULES(SDL, sdl, [ac_cv_my_have_sdl="yes"], [:])
229PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [ac_cv_my_have_sdl_mixer="yes"], [:])
230PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [ac_cv_my_have_sdl_image="yes"], [:])
231dnl
232dnl  Then the old sdl-config method
233if test "x${cross_compiling}" != xyes -a "${ac_cv_my_have_sdl}" != yes; then
234  AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
235  if test "${SDL_CONFIG}" != "no"; then
236    SDL_CFLAGS="${SDL_CFLAGS} `${SDL_CONFIG} --cflags`"
237    SDL_LIBS="${SDL_LIBS} `${SDL_CONFIG} --libs`"
238    ac_cv_my_have_sdl="yes"
239  fi
240fi
241dnl
242dnl  Maybe all this has failed, try direct inclusion
243save_CPPFLAGS="${CPPFLAGS}"
244save_LIBS="${LIBS}"
245CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
246LIBS="${LIBS} ${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
247AC_CHECK_HEADERS(SDL.h SDL/SDL.h, [ac_cv_my_have_sdl="yes"])
248AC_CHECK_HEADERS(SDL_mixer.h SDL/SDL_mixer.h, [ac_cv_my_have_sdl_mixer="yes"])
249AC_CHECK_HEADERS(SDL_image.h SDL/SDL_image.h, [ac_cv_my_have_sdl_image="yes"])
250AC_CHECK_LIB(SDL, main,
251 [SDL_LIBS="${SDL_LIBS} -lSDL"],
252 [ac_cv_my_have_sdl="no"])
253AC_CHECK_LIB(SDLmain, main,
254 [SDL_LIBS="${SDL_LIBS} -lSDLmain -lSDL"])
255AC_CHECK_LIB(SDL_mixer, main,
256 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"],
257 [ac_cv_my_have_sdl_mixer="no"])
258AC_CHECK_LIB(SDL_image, main,
259 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"],
260 [ac_cv_my_have_sdl_image="no"])
261SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
262SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
263CPPFLAGS="${save_CPPFLAGS}"
264LIBS="${save_LIBS}"
265if test "${ac_cv_my_have_sdl}" = "no"; then
266  AC_MSG_WARN([SDL not found])
267else
268  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL)
269fi
270if test "${ac_cv_my_have_sdl_mixer}" = "no"; then
271  AC_MSG_WARN([SDL_mixer not found])
272else
273  AC_DEFINE(USE_SDL_MIXER, 1, Define to 1 to use SDL_mixer)
274fi
275if test "${ac_cv_my_have_sdl_image}" = "no"; then
276  AC_MSG_WARN([SDL_image not found])
277else
278  AC_DEFINE(USE_SDL_IMAGE, 1, Define to 1 to use SDL_image)
279fi
280AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
281AM_CONDITIONAL(USE_SDL_MIXER, test "${ac_cv_my_have_sdl_mixer}" = "yes")
282AM_CONDITIONAL(USE_SDL_IMAGE, test "${ac_cv_my_have_sdl_image}" = "yes")
283
284
285dnl  Use Flex's FlexLexer.h or ours?
286ac_cv_my_have_flexlexer_h="no"
287AC_LANG_PUSH(C++)
288AC_CHECK_HEADERS(FlexLexer.h,
289 dnl  Ensure that FlexLexer::yleng is of type int, and not size_t like
290 dnl  on recent Apple systems. It would break all our existing code.
291 [AC_MSG_CHECKING(for FlexLexer.h validity)
292  AC_COMPILE_IFELSE(
293   [AC_LANG_PROGRAM([#include <FlexLexer.h>
294      class Foo : public FlexLexer
295      {
296          Foo() { int &test = yyleng; }
297      }],
298     [])],
299   [AC_MSG_RESULT(yes)
300    ac_cv_my_have_flexlexer_h="yes"],
301   [AC_MSG_RESULT(no)])])
302AC_LANG_POP(C++)
303if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
304  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/external/flex-2.5.35/include"
305fi
306
307
308dnl  Use NativeClient?
309ac_cv_my_have_nacl="no"
310AC_LANG_PUSH(C++)
311AC_CHECK_HEADERS(ppapi/cpp/instance.h,
312 [ac_cv_my_have_nacl="yes"
313  dnl  Disable this warning, it's too verbose with vector.h
314  CXXFLAGS="${CXXFLAGS} -Wno-sign-compare"])
315AC_LANG_POP(C++)
316AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
317
318
319dnl  Use Android? FIXME: super hacks!
320ac_cv_my_have_android="no"
321AC_CHECK_LIB(log, __android_log_vprint,
322 [ac_cv_my_have_android="yes"
323  LOL_LIBS="${LOL_LIBS} -llog -module"])
324AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
325
326
327dnl  Use EGL?
328ac_cv_my_have_egl="no"
329PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
330if test "${ac_cv_my_have_egl}" != "no"; then
331  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
332  EGL_LIBS="${EGL_LIBS} -lX11"
333fi
334AC_CHECK_LIB(EGL, main,
335 [ac_cv_my_have_egl="yes"
336  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
337  EGL_LIBS="-lEGL"])
338dnl  Raspberry Pi is different, check for it with extra libs; also we
339dnl  look for a different function to bypass autoconf caching
340AC_CHECK_LIB(EGL, eglGetDisplay,
341 [ac_cv_my_have_egl="yes"
342  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
343  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
344 [:],
345 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
346AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
347
348
349dnl Use libpng? (replacement for SDL_image)
350ac_cv_my_have_libpng="no"
351PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
352if test "${ac_cv_my_have_libpng}" != "no"; then
353  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
354fi
355AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
356
357
358dnl Use Windows GDI+?
359ac_cv_my_have_gdiplus="no"
360AC_LANG_PUSH(C++)
361AC_CHECK_HEADERS(gdiplus.h,
362 [ac_cv_my_have_gdiplus="yes"
363  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
364 [ac_cv_my_have_gdiplus="no"],
365 [#include <algorithm>
366  using std::min;
367  using std::max;
368  #include <windows.h>])
369AC_LANG_POP(C++)
370if test "${ac_cv_my_have_gdiplus}" != "no"; then
371  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
372fi
373AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
374
375
376dnl Use libcaca? (required for font generation)
377ac_cv_my_have_caca="no"
378PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
379if test "${ac_cv_my_have_caca}" != "no"; then
380  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
381fi
382AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
383
384
385dnl Use libpipi? (required for video recording)
386ac_cv_my_have_pipi="no"
387PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
388if test "${ac_cv_my_have_pipi}" != "no"; then
389  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
390  LOL_CFLAGS="${LOL_CFLAGS} ${PIPI_CFLAGS}"
391  LOL_LIBS="${LOL_LIBS} ${PIPI_LIBS}"
392fi
393AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
394
395
396dnl Use GTK+? (required for the deushax editor)
397ac_cv_my_have_gtkgl="no"
398PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
399PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
400if test "${ac_cv_my_have_gtkgl}" != "no"; then
401  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
402fi
403AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
404
405
406dnl  Can we build neercs?
407AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no")
408
409
410dnl  Extra libraries we may need
411AC_SUBST(MATH_LIBS)
412AC_SUBST(PAM_LIBS)
413AC_SUBST(UTIL_LIBS)
414
415dnl  How to use the Lol Engine inside this tree
416LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/src"
417LOL_CFLAGS="$LOL_CFLAGS -DLOL_SOURCE_SUBDIR=\\\"\$(subdir)\\\""
418LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
419LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
420
421dnl  Extra flags
422AC_SUBST(LOL_CFLAGS)
423AC_SUBST(LOL_LIBS)
424
425AC_SUBST(USE_DOT)
426
427AC_CONFIG_FILES(
428 [Makefile
429  src/Makefile
430  src/data/Makefile
431  src/data/font/Makefile
432  tutorial/Makefile
433  test/Makefile
434  test/math/Makefile
435  test/sandbox/Makefile
436  test/xolotl/Makefile
437  build/Makefile
438  binaries/Makefile
439  people/Makefile
440  games/Makefile
441  tools/Makefile
442  tools/vimlol/Makefile
443  tools/vslol/Makefile
444  doc/Makefile
445  doc/doxygen.cfg
446])
447AC_CONFIG_FILES(
448 [games/monsterz/Makefile
449])
450AC_CONFIG_FILES(
451 [games/deushax/Makefile
452  games/deushax/art/Makefile
453  games/deushax/art/test/Makefile
454  games/deushax/gfx/Makefile
455  games/deushax/maps/Makefile
456])
457AC_CONFIG_FILES(
458 [games/mrpigeon/Makefile
459])
460AC_CONFIG_FILES(
461 [games/orbital/Makefile
462])
463AC_CONFIG_FILES(
464 [tools/neercs/Makefile
465])
466AC_CONFIG_FILES(
467 [people/jnat/Makefile
468  people/jnat/TestProject/Makefile
469  people/peeweek/Makefile
470  people/touky/Makefile
471  people/jylam/Makefile
472  people/jylam/chat/Makefile
473])
474
475AC_OUTPUT
476
Note: See TracBrowser for help on using the repository browser.