source: trunk/configure.ac @ 2596

Last change on this file since 2596 was 2596, checked in by sam, 7 years ago

build: various compilation fixes.

File size: 14.5 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AC_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25AC_LIBTOOL_WIN32_DLL
26AM_PROG_LIBTOOL
27AC_LIBTOOL_CXX
28
29AC_C_CONST
30AC_C_INLINE
31
32dnl Ensure an error is thrown if pkg-config M4 files are not found.
33m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
34m4_pattern_forbid([^PKG_CHECK_MODULES$])
35m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
36
37dnl  Same for Lol Engine M4 files.
38m4_pattern_forbid([^LOL_])
39
40
41dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
42if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
43  export PKG_CONFIG_LIBDIR=/dev/null
44fi
45
46dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
47dnl now otherwise it might be set in an obscure if statement. Same thing for
48dnl PKG_PROG_PKG_CONFIG which needs to be called first.
49AC_EGREP_CPP(yes, foo)
50PKG_PROG_PKG_CONFIG()
51
52
53dnl  Check for a working implementation of sed
54AC_PROG_SED
55AC_MSG_CHECKING(for a sed that understands \t)
56if test "$(echo 'x\x' | "${SED}" 's/.*@<:@^x\t@:>@//')" != x; then
57  AC_MSG_RESULT(no)
58  AC_MSG_ERROR([[consider installing GNU sed]])
59else
60  AC_MSG_RESULT(yes)
61fi
62
63
64dnl conditional builds
65AC_ARG_ENABLE(debug,
66  [  --enable-debug          build debug versions of the game (default no)])
67AC_ARG_ENABLE(release,
68  [  --enable-release        build final release of the game (default no)])
69AC_ARG_ENABLE(experimental,
70  [  --enable-experimental   experimental build (default no)])
71AC_ARG_ENABLE(doc,
72  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
73
74
75dnl  Common C headers
76AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
77AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h unistd.h)
78AC_CHECK_HEADERS(execinfo.h)
79AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
80AC_CHECK_HEADERS(sys/wait.h)
81AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
82AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
83AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
84
85dnl  Common C++ headers
86AC_LANG_PUSH(C++)
87AC_CHECK_HEADERS(cxxabi.h)
88AC_LANG_POP(C++)
89
90dnl  Common C functions
91AC_CHECK_FUNCS(getenv system tmpfile tmpnam getcwd _getcwd backtrace_symbols)
92
93
94if test "${enable_debug}" = "yes"; then
95  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
96  OPT_CXXFLAGS="-O"
97else
98  OPT_CXXFLAGS="-O3 -ffast-math -fomit-frame-pointer"
99  OPT_LDFLAGS="-fno-strength-reduce"
100fi
101
102if test "${enable_release}" = "yes"; then
103  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
104  REL_CXXFLAGS=""
105else
106  REL_CXXFLAGS="-g"
107fi
108
109if test "${enable_experimental}" = "yes"; then
110  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
111fi
112
113# Build documentation?
114DOXYGEN="no"
115LATEX="no"
116if test "${enable_doc}" != "no"; then
117  AC_PATH_PROG(DOXYGEN, doxygen, no)
118  if test "${DOXYGEN}" != "no"; then
119    # Build LaTeX documentation?
120    AC_PATH_PROG(LATEX, pdflatex, no)
121    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
122    AC_PATH_PROG(DVIPS, dvips, no)
123    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
124      LATEX="no"
125    fi
126    if test "${LATEX}" != "no"; then
127      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
128      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
129        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
130          AC_MSG_RESULT(yes)
131        else
132          LATEX="no"
133          AC_MSG_RESULT(no)
134        fi
135      else
136        LATEX="no"
137        AC_MSG_RESULT(no)
138      fi
139    fi
140    AC_PATH_PROG(DOT, dot, no)
141    if test "${DOT}" != "no"; then
142      USE_DOT="YES"
143    else
144      USE_DOT="NO"
145    fi
146  fi
147fi
148AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
149AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
150AM_CONDITIONAL(USE_DOT, test "${DOT}" != "no")
151
152
153dnl  No exceptions
154LOL_TRY_CXXFLAGS(-fno-exceptions, [AM_CXXFLAGS="${AM_CXXFLAGS} -fno-exceptions"])
155LOL_TRY_CXXFLAGS(-fno-rtti, [AM_CXXFLAGS="${AM_CXXFLAGS} -fno-rtti"])
156
157dnl  Optimizations
158AM_CXXFLAGS="${AM_CXXFLAGS} ${REL_CXXFLAGS} ${OPT_CXXFLAGS}"
159AM_LDFLAGS="${AM_LDFLAGS} ${REL_LDFLAGS} ${OPT_LDFLAGS}"
160
161dnl  Debug symbols
162LOL_TRY_LDFLAGS(-rdynamic, [AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"])
163
164dnl  Code qui fait des warnings == code de porc == deux baffes dans ta gueule
165LOL_TRY_CXXFLAGS(-Wall, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wall"])
166LOL_TRY_CXXFLAGS(-Wextra, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wextra"])
167LOL_TRY_CXXFLAGS(-Wpointer-arith, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wpointer-arith"])
168LOL_TRY_CXXFLAGS(-Wcast-align, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wcast-align"])
169LOL_TRY_CXXFLAGS(-Wcast-qual, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wcast-qual"])
170LOL_TRY_CXXFLAGS(-Wshadow, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wshadow"])
171LOL_TRY_CXXFLAGS(-Wsign-compare, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wsign-compare"])
172
173dnl  Add these even though they're implicitly set, so that we can safely
174dnl  remove them from within a Makefile.
175LOL_TRY_CXXFLAGS(-Wmaybe-uninitialized, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wmaybe-uninitialized"])
176LOL_TRY_CXXFLAGS(-Wnarrowing, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wnarrowing"])
177LOL_TRY_CXXFLAGS(-Wunused, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wunused"])
178LOL_TRY_CXXFLAGS(-Wstrict-aliasing, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wstrict-aliasing"])
179LOL_TRY_CXXFLAGS(-Wparentheses, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wparentheses"])
180LOL_TRY_CXXFLAGS(-Wreorder, [AM_CXXFLAGS="${AM_CXXFLAGS} -Wreorder"])
181
182
183AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
184AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
185
186
187dnl  Unix-specific libutil
188AC_CHECK_LIB(util, forkpty,
189 [UTIL_LIBS="${UTIL_LIBS} -lutil"
190  dnl  Override future forkpty detection
191  ac_cv_func_forkpty="yes"])
192AC_CHECK_FUNCS(forkpty)
193
194
195dnl  GCC-specific symbol demangling
196AC_LANG_PUSH(C++)
197AC_TRY_LINK(
198 [#include <cxxabi.h>],
199 [abi::__cxa_demangle(NULL, 0, 0, NULL);],
200 [AC_DEFINE(HAVE_CXA_DEMANGLE, 1, Define to 1 if abi::__cxa_demangle is available)])
201AC_LANG_POP(C++)
202
203
204dnl  Are we on the PS3?
205ac_cv_my_have_ps3="no"
206AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
207 [ac_cv_my_have_ps3="yes"
208  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
209  dnl  For PSGL
210  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
211  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
212  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
213  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
214    CELL_SDK="${CELLSDK}"
215  fi
216  if test "x${enable_debug}" = xyes; then
217    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
218  elif test "x${enable_release}" = xyes; then
219    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
220  else
221    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
222  fi
223  dnl  For the runtime Cg compiler
224  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
225  dnl  For the PNG decoder
226  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
227  dnl  For the pad library
228  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
229  dnl  For the audio library
230  LOL_LIBS="${LOL_LIBS} -laudio_stub -lspurs_stub -lmstreamSPURSMP3"
231  dnl  For the filesystem support
232  LOL_LIBS="${LOL_LIBS} -lfs_stub"
233  dnl  Disable this warning, it's too verbose with vector.h
234  AM_CXXFLAGS="${AM_CXXFLAGS} -Wno-sign-compare"
235  AC_PATH_PROG(MAKE_FSELF, make_fself, no)
236  if test "${MAKE_FSELF}" = "no"; then
237    AC_MSG_ERROR([[Building for PS3 but make_fself not found]])
238  fi],
239 [MAKE_FSELF=no])
240AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
241
242
243dnl  Are we building using MinGW?
244LOL_TRY_CXXFLAGS(-mwindows -mwin32,
245 [AM_CXXFLAGS="${AM_CXXFLAGS} -mwindows -mwin32"
246  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"])
247
248
249dnl  Are we on the Xbox 360?
250dnl  Answer: NO! we don't know how to build for it anyway
251AM_CONDITIONAL(USE_X360, false)
252
253
254dnl  Are we on an OS X or iOS platform?
255LOL_TRY_LDFLAGS(-framework Foundation,
256 [LOL_LIBS="${LOL_LIBS} -framework Foundation"])
257LOL_TRY_LDFLAGS(-framework CoreGraphics,
258 [LOL_LIBS="${LOL_LIBS} -framework CoreGraphics"])
259LOL_TRY_LDFLAGS(-framework CoreData,
260 [LOL_LIBS="${LOL_LIBS} -framework CoreData"])
261LOL_TRY_LDFLAGS(-framework UIKit,
262 [LOL_LIBS="${LOL_LIBS} -framework UIKit"])
263
264
265dnl Are we on a Direct3D 9 platform?
266#ac_cv_my_have_d3d9="no"
267#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
268#if test "${ac_cv_my_have_d3d9}" != "no"; then
269#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
270#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
271#fi
272#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
273
274LOL_CHECK_OPENGL
275
276LOL_CHECK_SDL
277
278dnl  Use Flex's FlexLexer.h or ours?
279ac_cv_my_have_flexlexer_h="no"
280AC_LANG_PUSH(C++)
281AC_CHECK_HEADERS(FlexLexer.h,
282 dnl  Ensure that FlexLexer::yleng is of type int, and not size_t like
283 dnl  on recent Apple systems. It would break all our existing code.
284 [AC_MSG_CHECKING(for FlexLexer.h validity)
285  AC_COMPILE_IFELSE(
286   [AC_LANG_PROGRAM([#include <FlexLexer.h>
287      class Foo : public FlexLexer
288      {
289          Foo() { int &test = yyleng; }
290      }],
291     [])],
292   [AC_MSG_RESULT(yes)
293    ac_cv_my_have_flexlexer_h="yes"],
294   [AC_MSG_RESULT(no)])])
295AC_LANG_POP(C++)
296if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
297  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/external/flex-2.5.35/include"
298fi
299
300
301dnl  Use NativeClient?
302ac_cv_my_have_nacl="no"
303AC_LANG_PUSH(C++)
304AC_CHECK_HEADERS(ppapi/cpp/instance.h,
305 [ac_cv_my_have_nacl="yes"
306  LOL_LIBS="${LOL_LIBS} -lnosys"])
307AC_LANG_POP(C++)
308AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
309
310
311dnl  Use Android? FIXME: super hacks!
312ac_cv_my_have_android="no"
313AC_CHECK_LIB(log, __android_log_vprint,
314 [ac_cv_my_have_android="yes"
315  LOL_LIBS="${LOL_LIBS} -llog -landroid -module -lEGL -lGLESv2"])
316AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
317
318
319dnl  Use EGL?
320ac_cv_my_have_egl="no"
321PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
322if test "${ac_cv_my_have_egl}" != "no"; then
323  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
324  EGL_LIBS="${EGL_LIBS} -lX11"
325fi
326AC_CHECK_LIB(EGL, main,
327 [ac_cv_my_have_egl="yes"
328  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
329  EGL_LIBS="-lEGL"])
330dnl  Raspberry Pi is different, check for it with extra libs; also we
331dnl  look for a different function to bypass autoconf caching
332AC_CHECK_LIB(EGL, eglGetDisplay,
333 [ac_cv_my_have_egl="yes"
334  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
335  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
336 [:],
337 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
338AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
339
340
341dnl Use libpng? (replacement for SDL_image)
342ac_cv_my_have_libpng="no"
343PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
344if test "${ac_cv_my_have_libpng}" != "no"; then
345  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
346fi
347AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
348
349
350dnl Use Windows GDI+?
351ac_cv_my_have_gdiplus="no"
352AC_LANG_PUSH(C++)
353AC_CHECK_HEADERS(gdiplus.h,
354 [ac_cv_my_have_gdiplus="yes"
355  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
356 [ac_cv_my_have_gdiplus="no"],
357 [#include <algorithm>
358  using std::min;
359  using std::max;
360  #include <windows.h>])
361AC_LANG_POP(C++)
362if test "${ac_cv_my_have_gdiplus}" != "no"; then
363  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
364fi
365AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
366
367
368dnl Use libcaca? (required for font generation)
369ac_cv_my_have_caca="no"
370PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
371if test "${ac_cv_my_have_caca}" != "no"; then
372  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
373fi
374AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
375
376
377dnl Use libpipi? (required for video recording)
378ac_cv_my_have_pipi="no"
379PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
380if test "${ac_cv_my_have_pipi}" != "no"; then
381  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
382  LOL_CFLAGS="${LOL_CFLAGS} ${PIPI_CFLAGS}"
383  LOL_LIBS="${LOL_LIBS} ${PIPI_LIBS}"
384fi
385AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
386
387
388dnl Use GTK+? (required for the deushax editor)
389ac_cv_my_have_gtkgl="no"
390PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
391PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
392if test "${ac_cv_my_have_gtkgl}" != "no"; then
393  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
394fi
395AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
396
397
398dnl  Can we build neercs?
399AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no")
400
401
402dnl  Extra libraries we may need
403AC_SUBST(MATH_LIBS)
404AC_SUBST(PAM_LIBS)
405AC_SUBST(UTIL_LIBS)
406
407dnl  How to use the Lol Engine outside this tree
408LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
409LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
410LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/liblolcore.a"
411LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/bullet/liblolbullet.a"
412LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/lua/liblollua.a"
413
414dnl  How to use the Lol Engine inside this tree
415AM_CPPFLAGS="${AM_CPPFLAGS} -I\$(top_srcdir)/src"
416AM_CPPFLAGS="${AM_CPPFLAGS} -DLOL_CONFIG_SOURCESUBDIR=\\\"\$(subdir)\\\""
417AM_CPPFLAGS="${AM_CPPFLAGS} ${LOL_CFLAGS}"
418AM_LDFLAGS="${AM_LDFLAGS} ${LOL_DEPS}"
419AM_LDFLAGS="${AM_LDFLAGS} ${LOL_LIBS}"
420
421dnl  Extra flags
422AC_SUBST(LOL_CFLAGS)
423AC_SUBST(LOL_LIBS)
424AC_SUBST(LOL_DEPS)
425
426AC_SUBST(AM_CFLAGS)
427AC_SUBST(AM_CPPFLAGS)
428AC_SUBST(AM_CXXFLAGS)
429AC_SUBST(AM_LDFLAGS)
430
431AC_SUBST(USE_DOT)
432
433AC_CONFIG_FILES(
434 [Makefile
435  src/Makefile
436  src/bullet/Makefile
437  src/lua/Makefile
438  src/data/Makefile
439  src/data/font/Makefile
440  tutorial/Makefile
441  test/Makefile
442  test/math/Makefile
443  test/sandbox/Makefile
444  test/xolotl/Makefile
445  build/Makefile
446  binaries/Makefile
447  people/Makefile
448  games/Makefile
449  tools/Makefile
450  tools/vimlol/Makefile
451  tools/vslol/Makefile
452  doc/Makefile
453  doc/doxygen.cfg
454])
455AC_CONFIG_FILES(
456 [games/monsterz/Makefile
457])
458AC_CONFIG_FILES(
459 [games/deushax/Makefile
460  games/deushax/art/Makefile
461  games/deushax/art/test/Makefile
462  games/deushax/gfx/Makefile
463  games/deushax/maps/Makefile
464])
465AC_CONFIG_FILES(
466 [games/mrpigeon/Makefile
467])
468AC_CONFIG_FILES(
469 [games/orbital/Makefile
470])
471AC_CONFIG_FILES(
472 [tools/neercs/Makefile
473])
474AC_CONFIG_FILES(
475 [people/jnat/Makefile
476  people/jnat/TestProject/Makefile
477  people/peeweek/Makefile
478  people/peeweek/private/Makefile
479  people/touky/Makefile
480  people/touky/private/Makefile
481  people/touky/private/tactics/Makefile
482  people/touky/private/the_unfortunate_voronoid/Makefile
483  people/jylam/Makefile
484  people/jylam/private/Makefile
485  people/jylam/private/chat/Makefile
486])
487
488AC_OUTPUT
489
Note: See TracBrowser for help on using the repository browser.