source: trunk/configure.ac @ 2655

Last change on this file since 2655 was 2655, checked in by sam, 7 years ago

build: fix the FlexLexer.h configure check.

File size: 15.4 KB
Line 
1dnl configure script for Lol Engine
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([subdir-objects no-define tar-ustar silent-rules])
8dnl AM_MAINTAINER_MODE
9AM_DEFAULT_VERBOSITY=0
10
11dnl Versioning of the separate software we ship
12LOLUNIT_VERSION=0.1
13AC_SUBST(LOLUNIT_VERSION)
14LOLREMEZ_VERSION=0.2
15AC_SUBST(LOLREMEZ_VERSION)
16
17AC_CONFIG_HEADER(config.h)
18
19AM_PROG_CC_C_O
20AC_PROG_CPP
21AC_PROG_CXX
22AC_PROG_CXXCPP
23AC_PROG_RANLIB
24
25dnl  Check that the C++ compiler really works
26AC_LANG_PUSH(C++)
27AC_MSG_CHECKING(for a fully working C++ compiler)
28AC_TRY_LINK([], [],
29 [AC_MSG_RESULT(yes)],
30 [AC_MSG_RESULT(no)
31  AC_MSG_ERROR([[C++ compiler cannot link executables]])])
32AC_LANG_POP(C++)
33
34AC_LIBTOOL_WIN32_DLL
35AM_PROG_LIBTOOL
36AC_LIBTOOL_CXX
37
38AC_C_CONST
39AC_C_INLINE
40
41dnl Ensure an error is thrown if pkg-config M4 files are not found.
42m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
43m4_pattern_forbid([^PKG_CHECK_MODULES$])
44m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
45
46dnl  Same for Lol Engine M4 files.
47m4_pattern_forbid([^LOL_])
48
49
50dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
51if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
52  export PKG_CONFIG_LIBDIR=/dev/null
53fi
54
55dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
56dnl now otherwise it might be set in an obscure if statement. Same thing for
57dnl PKG_PROG_PKG_CONFIG which needs to be called first.
58AC_EGREP_CPP(yes, foo)
59PKG_PROG_PKG_CONFIG()
60
61
62dnl  Check for a working implementation of sed
63AC_PROG_SED
64AC_MSG_CHECKING(for a sed that understands \t)
65if test "$(echo 'x\x' | "${SED}" 's/.*@<:@^x\t@:>@//')" != x; then
66  AC_MSG_RESULT(no)
67  AC_MSG_ERROR([[consider installing GNU sed]])
68else
69  AC_MSG_RESULT(yes)
70fi
71
72
73dnl conditional builds
74AC_ARG_ENABLE(debug,
75  [  --enable-debug          build debug versions of the game (default no)])
76AC_ARG_ENABLE(release,
77  [  --enable-release        build final release of the game (default no)])
78AC_ARG_ENABLE(experimental,
79  [  --enable-experimental   experimental build (default no)])
80AC_ARG_ENABLE(doc,
81  [  --enable-doc            build documentation (needs doxygen and LaTeX)])
82
83
84dnl  Common C headers
85AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
86AC_CHECK_HEADERS(fastmath.h pthread.h libutil.h util.h pty.h glob.h unistd.h)
87AC_CHECK_HEADERS(execinfo.h)
88AC_CHECK_HEADERS(sys/ioctl.h sys/ptrace.h sys/stat.h sys/syscall.h sys/user.h)
89AC_CHECK_HEADERS(sys/wait.h sys/time.h)
90AC_CHECK_HEADERS(linux/kdev_t.h linux/major.h)
91AC_CHECK_HEADERS(security/pam_appl.h security/pam_misc.h)
92AC_CHECK_HEADERS(pam/pam_appl.h pam/pam_misc.h)
93
94dnl  Common C++ headers
95AC_LANG_PUSH(C++)
96AC_CHECK_HEADERS(cxxabi.h)
97AC_LANG_POP(C++)
98
99dnl  Common C functions
100AC_CHECK_FUNCS(getenv system tmpfile tmpnam getcwd _getcwd backtrace_symbols)
101AC_CHECK_FUNCS(gettimeofday usleep)
102
103
104if test "${enable_debug}" = "yes"; then
105  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
106  OPT_CXXFLAGS="-O"
107else
108  OPT_CXXFLAGS="-O3 -ffast-math -fomit-frame-pointer"
109  OPT_LDFLAGS="-fno-strength-reduce"
110fi
111
112if test "${enable_release}" = "yes"; then
113  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
114  REL_CXXFLAGS=""
115else
116  REL_CXXFLAGS="-g"
117fi
118
119if test "${enable_experimental}" = "yes"; then
120  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
121fi
122
123# Build documentation?
124DOXYGEN="no"
125LATEX="no"
126if test "${enable_doc}" != "no"; then
127  AC_PATH_PROG(DOXYGEN, doxygen, no)
128  if test "${DOXYGEN}" != "no"; then
129    # Build LaTeX documentation?
130    AC_PATH_PROG(LATEX, pdflatex, no)
131    AC_PATH_PROG(KPSEWHICH, kpsewhich, no)
132    AC_PATH_PROG(DVIPS, dvips, no)
133    if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then
134      LATEX="no"
135    fi
136    if test "${LATEX}" != "no"; then
137      AC_MSG_CHECKING(for a4.sty and a4wide.sty)
138      if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then
139        if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then
140          AC_MSG_RESULT(yes)
141        else
142          LATEX="no"
143          AC_MSG_RESULT(no)
144        fi
145      else
146        LATEX="no"
147        AC_MSG_RESULT(no)
148      fi
149    fi
150    AC_PATH_PROG(DOT, dot, no)
151    if test "${DOT}" != "no"; then
152      USE_DOT="YES"
153    else
154      USE_DOT="NO"
155    fi
156  fi
157fi
158AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")
159AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")
160AM_CONDITIONAL(USE_DOT, test "${DOT}" != "no")
161
162
163dnl  No exceptions
164LOL_TRY_CXXFLAGS(-fno-exceptions, [AM_CXXFLAGS="${AM_CXXFLAGS} -fno-exceptions"])
165LOL_TRY_CXXFLAGS(-fno-rtti, [AM_CXXFLAGS="${AM_CXXFLAGS} -fno-rtti"])
166
167dnl  Optimizations
168AM_CXXFLAGS="${AM_CXXFLAGS} ${REL_CXXFLAGS} ${OPT_CXXFLAGS}"
169AM_LDFLAGS="${AM_LDFLAGS} ${REL_LDFLAGS} ${OPT_LDFLAGS}"
170
171dnl  Debug symbols
172LOL_TRY_LDFLAGS(-rdynamic, [AM_LDFLAGS="${AM_LDFLAGS} -rdynamic"])
173
174dnl  Code qui fait des warnings == code de porc == deux baffes dans ta gueule
175LOL_TRY_CXXFLAGS(-Wall, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wall"])
176LOL_TRY_CXXFLAGS(-Wextra, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wextra"])
177LOL_TRY_CXXFLAGS(-Wpointer-arith, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wpointer-arith"])
178LOL_TRY_CXXFLAGS(-Wcast-align, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wcast-align"])
179LOL_TRY_CXXFLAGS(-Wcast-qual, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wcast-qual"])
180LOL_TRY_CXXFLAGS(-Wshadow, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wshadow"])
181LOL_TRY_CXXFLAGS(-Wsign-compare, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wsign-compare"])
182
183dnl  Add these even though they're implicitly set, so that we can safely
184dnl  remove them from within a Makefile.
185LOL_TRY_CXXFLAGS(-Wmaybe-uninitialized, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wmaybe-uninitialized"])
186LOL_TRY_CXXFLAGS(-Wnarrowing, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wnarrowing"])
187LOL_TRY_CXXFLAGS(-Wunused, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wunused"])
188LOL_TRY_CXXFLAGS(-Wstrict-aliasing, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wstrict-aliasing"])
189LOL_TRY_CXXFLAGS(-Wparentheses, [AM_CPPFLAGS="${AM_CPPFLAGS} -Wparentheses"])
190LOL_TRY_CXXFLAGS(-Wreorder, [AM_CXXFLAGS="${AM_CXXFLAGS} -Wreorder"])
191
192
193AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
194AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
195
196
197dnl  Unix-specific libutil
198AC_CHECK_LIB(util, forkpty,
199 [UTIL_LIBS="${UTIL_LIBS} -lutil"
200  dnl  Override future forkpty detection
201  ac_cv_func_forkpty="yes"])
202AC_CHECK_FUNCS(forkpty)
203
204
205dnl  GCC-specific symbol demangling
206AC_LANG_PUSH(C++)
207AC_TRY_LINK(
208 [#include <cxxabi.h>],
209 [abi::__cxa_demangle(NULL, 0, 0, NULL);],
210 [AC_DEFINE(HAVE_CXA_DEMANGLE, 1, Define to 1 if abi::__cxa_demangle is available)])
211AC_LANG_POP(C++)
212
213
214dnl  Are we on the PS3?
215ac_cv_my_have_ps3="no"
216AC_CHECK_LIB(sysmodule_stub, cellSysmoduleLoadModule,
217 [ac_cv_my_have_ps3="yes"
218  LOL_LIBS="${LOL_LIBS} -lsysmodule_stub -lsysutil_stub -lresc_stub"
219  dnl  For PSGL
220  AC_DEFINE(HAVE_GLES_2X, 1, Define to 1 if GLES 2.x is available) # FIXME: hack
221  GL_LIBS="${GL_LIBS} -lPSGL -lgcm_cmd -lgcm_sys_stub"
222  dnl  This is the old way; we now use CELL_SDK instead of CELLSDK
223  if test "x${CELLSDK}" != x -a "x${CELL_SDK}" = x; then
224    CELL_SDK="${CELLSDK}"
225  fi
226  if test "x${enable_debug}" = xyes; then
227    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/debug"
228  elif test "x${enable_release}" = xyes; then
229    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/ultra-opt"
230  else
231    GL_LIBS="${GL_LIBS} -L${CELL_SDK}/target/ppu/lib/PSGL/RSX/opt"
232  fi
233  dnl  For the runtime Cg compiler
234  GL_LIBS="${GL_LIBS} -lcgc -lPSGLcgc"
235  dnl  For the PNG decoder
236  LOL_LIBS="${LOL_LIBS} -lpngdec_stub"
237  dnl  For the pad library
238  LOL_LIBS="${LOL_LIBS} -lio_stub -lusbd_stub -lpadfilter"
239  dnl  For the audio library
240  LOL_LIBS="${LOL_LIBS} -laudio_stub -lspurs_stub -lmstreamSPURSMP3"
241  dnl  For the filesystem support
242  LOL_LIBS="${LOL_LIBS} -lfs_stub"
243  dnl  Disable this warning, it's too verbose with vector.h
244  AM_CXXFLAGS="${AM_CXXFLAGS} -Wno-sign-compare"
245  AC_PATH_PROG(MAKE_FSELF, make_fself, no)
246  if test "${MAKE_FSELF}" = "no"; then
247    AC_MSG_ERROR([[Building for PS3 but make_fself not found]])
248  fi],
249 [MAKE_FSELF=no])
250AM_CONDITIONAL(USE_PS3, test "${ac_cv_my_have_ps3}" != "no")
251
252
253dnl  Are we building using MinGW?
254LOL_TRY_CXXFLAGS(-mwindows -mwin32,
255 [AM_CXXFLAGS="${AM_CXXFLAGS} -mwindows -mwin32"
256  LOL_LIBS="${LOL_LIBS} -uWinMain -u_WinMain@16"])
257
258
259dnl  Are we building using Emscripten?
260ac_cv_my_have_emscripten="no"
261AC_CHECK_HEADERS(emscripten.h,
262 [ac_cv_my_have_emscripten="yes"
263  AM_CXXFLAGS="${AM_CXXFLAGS} -s ALLOW_MEMORY_GROWTH=1"
264  dnl  HACK: until emcc properly adds these to EMSDK_OPTS
265  CPPFLAGS="${CPPFLAGS} -U__i386__ -U__x86_64__ -U__i386 -U__x86_64 -Ui386 -Ux86_64"
266  CPPFLAGS="${CPPFLAGS} -U__SSE__ -U__SSE2__ -U__MMX__ -UX87_DOUBLE_ROUNDING"
267  CPPFLAGS="${CPPFLAGS} -UHAVE_GCC_ASM_FOR_X87 -DEMSCRIPTEN -U__STRICT_ANSI__"
268  CPPFLAGS="${CPPFLAGS} -U__CYGWIN__"])
269AM_CONDITIONAL(USE_EMSCRIPTEN, test "${ac_cv_my_have_emscripten}" != "no")
270
271
272dnl  Are we on the Xbox 360?
273dnl  Answer: NO! we don't know how to build for it anyway
274AM_CONDITIONAL(USE_X360, false)
275
276
277dnl  Are we on an OS X or iOS platform?
278LOL_TRY_LDFLAGS(-framework Foundation,
279 [LOL_LIBS="${LOL_LIBS} -framework Foundation"])
280LOL_TRY_LDFLAGS(-framework CoreGraphics,
281 [LOL_LIBS="${LOL_LIBS} -framework CoreGraphics"])
282LOL_TRY_LDFLAGS(-framework CoreData,
283 [LOL_LIBS="${LOL_LIBS} -framework CoreData"])
284LOL_TRY_LDFLAGS(-framework UIKit,
285 [LOL_LIBS="${LOL_LIBS} -framework UIKit"])
286
287
288dnl Are we on a Direct3D 9 platform?
289#ac_cv_my_have_d3d9="no"
290#AC_CHECK_HEADERS(d3d9.h, [ac_cv_my_have_d3d9="yes"])
291#if test "${ac_cv_my_have_d3d9}" != "no"; then
292#  D3D_LIBS="${D3D_LIBS} -ld3d9 -ld3dx9 -lxinput"
293#  AC_DEFINE(USE_D3D9, 1, Define to 1 to use DirectX 9)
294#fi
295#AM_CONDITIONAL(USE_D3D9, test "${ac_cv_my_have_d3d9}" != "no")
296
297LOL_CHECK_OPENGL
298
299LOL_CHECK_SDL
300
301dnl  Use Flex's FlexLexer.h or ours?
302ac_cv_my_have_flexlexer_h="no"
303AC_LANG_PUSH(C++)
304AC_CHECK_HEADERS(FlexLexer.h,
305 dnl  Ensure that FlexLexer::yleng is of type int, and not size_t like
306 dnl  on recent Apple systems. It would break all our existing code.
307 [AC_MSG_CHECKING(for FlexLexer.h validity)
308  AC_COMPILE_IFELSE(
309   [AC_LANG_PROGRAM([#include <FlexLexer.h>
310      class Foo : public FlexLexer
311      {
312          Foo() { int &test = yyleng; }
313      };],
314     [])],
315   [AC_MSG_RESULT(yes)
316    ac_cv_my_have_flexlexer_h="yes"],
317   [AC_MSG_RESULT(no)])])
318AC_LANG_POP(C++)
319if test "x${ac_cv_my_have_flexlexer_h}" = "xno"; then
320  LOL_CFLAGS="$LOL_CFLAGS -I\$(top_srcdir)/external/flex-2.5.35/include"
321fi
322
323
324dnl  Use NativeClient?
325ac_cv_my_have_nacl="no"
326AC_LANG_PUSH(C++)
327AC_CHECK_HEADERS(ppapi/cpp/instance.h,
328 [ac_cv_my_have_nacl="yes"
329  LOL_LIBS="${LOL_LIBS} -lnosys"])
330AC_LANG_POP(C++)
331AM_CONDITIONAL(USE_NACL, test "${ac_cv_my_have_nacl}" != "no")
332
333
334dnl  Use Android? FIXME: super hacks!
335ac_cv_my_have_android="no"
336AC_CHECK_LIB(log, __android_log_vprint,
337 [ac_cv_my_have_android="yes"
338  LOL_LIBS="${LOL_LIBS} -llog -landroid -module -lEGL -lGLESv2"])
339AM_CONDITIONAL(USE_ANDROID, test "${ac_cv_my_have_android}" != "no")
340
341
342dnl  Use EGL?
343ac_cv_my_have_egl="no"
344PKG_CHECK_MODULES(EGL, egl, [ac_cv_my_have_egl="yes"], [:])
345if test "${ac_cv_my_have_egl}" != "no"; then
346  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
347  EGL_LIBS="${EGL_LIBS} -lX11"
348fi
349AC_CHECK_LIB(EGL, main,
350 [ac_cv_my_have_egl="yes"
351  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
352  EGL_LIBS="-lEGL"])
353dnl  Raspberry Pi is different, check for it with extra libs; also we
354dnl  look for a different function to bypass autoconf caching
355AC_CHECK_LIB(EGL, eglGetDisplay,
356 [ac_cv_my_have_egl="yes"
357  AC_DEFINE(USE_EGL, 1, Define to 1 to use libegl)
358  EGL_LIBS="-lEGL -lvcos -lvchiq_arm -lbcm_host -lGLESv2"],
359 [:],
360 [-lvcos -lvchiq_arm -lbcm_host -lGLESv2])
361AM_CONDITIONAL(USE_EGL, test "${ac_cv_my_have_egl}" != "no")
362
363
364dnl Use libpng? (replacement for SDL_image)
365ac_cv_my_have_libpng="no"
366PKG_CHECK_MODULES(LIBPNG, libpng, [ac_cv_my_have_libpng="yes"], [:])
367if test "${ac_cv_my_have_libpng}" != "no"; then
368  AC_DEFINE(USE_LIBPNG, 1, Define to 1 to use libpng)
369fi
370AM_CONDITIONAL(USE_LIBPNG, test "${ac_cv_my_have_libpng}" != "no")
371
372
373dnl Use Windows GDI+?
374ac_cv_my_have_gdiplus="no"
375AC_LANG_PUSH(C++)
376AC_CHECK_HEADERS(gdiplus.h,
377 [ac_cv_my_have_gdiplus="yes"
378  LOL_LIBS="${LOL_LIBS} -lgdiplus"],
379 [ac_cv_my_have_gdiplus="no"],
380 [#include <algorithm>
381  using std::min;
382  using std::max;
383  #include <windows.h>])
384AC_LANG_POP(C++)
385if test "${ac_cv_my_have_gdiplus}" != "no"; then
386  AC_DEFINE(USE_GDIPLUS, 1, Define to 1 to use GDI+)
387fi
388AM_CONDITIONAL(USE_GDIPLUS, test "${ac_cv_my_have_gdiplus}" = "yes")
389
390
391dnl Use libcaca? (required for font generation)
392ac_cv_my_have_caca="no"
393PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
394if test "${ac_cv_my_have_caca}" != "no"; then
395  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
396fi
397AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
398
399
400dnl Use libpipi? (required for video recording)
401ac_cv_my_have_pipi="no"
402PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
403if test "${ac_cv_my_have_pipi}" != "no"; then
404  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
405  LOL_CFLAGS="${LOL_CFLAGS} ${PIPI_CFLAGS}"
406  LOL_LIBS="${LOL_LIBS} ${PIPI_LIBS}"
407fi
408AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
409
410
411dnl Use GTK+? (required for the deushax editor)
412ac_cv_my_have_gtkgl="no"
413PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
414PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
415if test "${ac_cv_my_have_gtkgl}" != "no"; then
416  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
417fi
418AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
419
420
421dnl  Can we build neercs?
422AM_CONDITIONAL(BUILD_NEERCS, test "${ac_cv_my_have_caca}" != "no")
423
424
425dnl  Extra libraries we may need
426AC_SUBST(MATH_LIBS)
427AC_SUBST(PAM_LIBS)
428AC_SUBST(UTIL_LIBS)
429
430dnl  How to use the Lol Engine outside this tree
431LOL_CFLAGS="$LOL_CFLAGS $SDL_CFLAGS $GL_CFLAGS $EGL_CFLAGS $LIBPNG_CFLAGS"
432LOL_LIBS="$LOL_LIBS $SDL_LIBS $GL_LIBS $EGL_LIBS $LIBPNG_LIBS $D3D_LIBS"
433LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/liblolcore.a"
434LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/bullet/liblolbullet.a"
435LOL_DEPS="${LOL_DEPS} \$(top_builddir)/src/lua/liblollua.a"
436
437dnl  How to use the Lol Engine inside this tree
438AM_CPPFLAGS="${AM_CPPFLAGS} -I\$(top_srcdir)/src"
439AM_CPPFLAGS="${AM_CPPFLAGS} -DLOL_CONFIG_SOURCESUBDIR=\\\"\$(subdir)\\\""
440AM_CPPFLAGS="${AM_CPPFLAGS} ${LOL_CFLAGS}"
441AM_LDFLAGS="${AM_LDFLAGS} ${LOL_DEPS}"
442AM_LDFLAGS="${AM_LDFLAGS} ${LOL_LIBS}"
443
444dnl  Extra flags
445AC_SUBST(LOL_CFLAGS)
446AC_SUBST(LOL_LIBS)
447AC_SUBST(LOL_DEPS)
448
449AC_SUBST(AM_CFLAGS)
450AC_SUBST(AM_CPPFLAGS)
451AC_SUBST(AM_CXXFLAGS)
452AC_SUBST(AM_LDFLAGS)
453
454AC_SUBST(USE_DOT)
455
456AC_CONFIG_FILES(
457 [Makefile
458  src/Makefile
459  src/bullet/Makefile
460  src/lua/Makefile
461  src/data/Makefile
462  src/data/font/Makefile
463  tutorial/Makefile
464  test/Makefile
465  test/math/Makefile
466  test/sandbox/Makefile
467  test/xolotl/Makefile
468  build/Makefile
469  binaries/Makefile
470  people/Makefile
471  games/Makefile
472  tools/Makefile
473  tools/vimlol/Makefile
474  tools/vslol/Makefile
475  doc/Makefile
476  doc/doxygen.cfg
477])
478AC_CONFIG_FILES(
479 [games/monsterz/Makefile
480])
481AC_CONFIG_FILES(
482 [games/deushax/Makefile
483  games/deushax/art/Makefile
484  games/deushax/art/test/Makefile
485  games/deushax/gfx/Makefile
486  games/deushax/maps/Makefile
487])
488AC_CONFIG_FILES(
489 [games/mrpigeon/Makefile
490])
491AC_CONFIG_FILES(
492 [games/orbital/Makefile
493])
494AC_CONFIG_FILES(
495 [tools/neercs/Makefile
496])
497AC_CONFIG_FILES(
498 [people/jnat/Makefile
499  people/jnat/TestProject/Makefile
500  people/peeweek/Makefile
501  people/peeweek/private/Makefile
502  people/touky/Makefile
503  people/touky/private/Makefile
504  people/touky/private/tactics/Makefile
505  people/touky/private/the_unfortunate_voronoid/Makefile
506  people/jylam/Makefile
507  people/jylam/private/Makefile
508  people/jylam/private/chat/Makefile
509])
510
511AC_OUTPUT
512
Note: See TracBrowser for help on using the repository browser.