source: trunk/configure.ac @ 658

Last change on this file since 658 was 658, checked in by sam, 9 years ago

Get rid of the SHADER_CRAP macro and use LOL_EXPERIMENTAL instead,
together with the --enable-experimental flag. Use LOL_DEBUG and
LOL_RELEASE instead of the previous values.

File size: 4.7 KB
Line 
1# $Id$
2
3AC_INIT(lolengine, 0.0)
4AC_PREREQ(2.50)
5AC_CONFIG_AUX_DIR(.auto)
6AC_CANONICAL_SYSTEM
7AM_INIT_AUTOMAKE([no-define tar-ustar])
8dnl AM_MAINTAINER_MODE
9
10AM_CONFIG_HEADER(config.h)
11
12AM_PROG_CC_C_O
13AC_PROG_CPP
14AC_PROG_CXX
15AC_PROG_CXXCPP
16AC_PROG_RANLIB
17
18AC_LIBTOOL_WIN32_DLL
19AM_PROG_LIBTOOL
20AC_LIBTOOL_CXX
21
22AC_C_CONST
23AC_C_INLINE
24
25dnl Ensure an error is thrown if pkg-config M4 files are not found.
26m4_pattern_allow([^PKG_CONFIG_LIBDIR$])
27m4_pattern_forbid([^PKG_CHECK_MODULES$])
28m4_pattern_forbid([^PKG_PROG_PKG_CONFIG$])
29
30dnl Do not use PKG_CONFIG_LIBDIR when cross-compiling.
31if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then
32  export PKG_CONFIG_LIBDIR=/dev/null
33fi
34
35dnl AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right
36dnl now otherwise it might be set in an obscure if statement. Same thing for
37dnl PKG_PROG_PKG_CONFIG which needs to be called first.
38AC_EGREP_CPP(yes, foo)
39PKG_PROG_PKG_CONFIG()
40
41dnl conditional builds
42AC_ARG_ENABLE(debug,
43  [  --enable-debug          build debug versions of the game (default no)])
44AC_ARG_ENABLE(release,
45  [  --enable-release        build final release of the game (default no)])
46AC_ARG_ENABLE(experimental,
47  [  --enable-experimental   experimental build (default no)])
48
49AC_ARG_ENABLE(cppunit,
50  [  --enable-cppunit        use cppunit for unit tests (autodetected)])
51
52AC_CHECK_HEADERS(stdio.h stdarg.h inttypes.h endian.h stdint.h getopt.h)
53
54if test "${enable_debug}" = "yes"; then
55  AC_DEFINE(LOL_DEBUG, 1, Define to 1 to activate debug)
56  OPT="-O0"
57else
58  OPT="-O2"
59fi
60
61if test "${enable_release}" = "yes"; then
62  AC_DEFINE(LOL_RELEASE, 1, Define to 1 to activate final release)
63  REL=""
64else
65  REL="-g"
66fi
67
68if test "${enable_experimental}" = "yes"; then
69  AC_DEFINE(LOL_EXPERIMENTAL, 1, Define to 1 to activate experimental build)
70fi
71
72# Optimizations
73CXXFLAGS="${CXXFLAGS} ${REL} ${OPT} -fno-strength-reduce -fomit-frame-pointer"
74# Code qui fait des warnings == code de porc == deux baffes dans ta gueule
75CXXFLAGS="${CXXFLAGS} -Wall -Wextra -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"
76
77AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")
78
79# Use SDL? (always required)
80ac_cv_my_have_sdl="yes"
81AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
82if test "${SDL_CONFIG}" != "no"; then
83  SDL_CFLAGS="${SDL_CFLAGS} `sdl-config --cflags`"
84  SDL_LIBS="${SDL_LIBS} `sdl-config --libs`"
85fi
86PKG_CHECK_MODULES(SDL, sdl, [:],
87 [SDL_LIBS="${SDL_LIBS} -lSDL"])
88AC_CHECK_LIB(GL, glLoadIdentity, SDL_LIBS="${SDL_LIBS} -lGL") # FIXME: hackish
89PKG_CHECK_MODULES(SDLMIXER, SDL_mixer, [:],
90 [SDLMIXER_LIBS="${SDLMIXER_LIBS} -lSDL_mixer"])
91PKG_CHECK_MODULES(SDLIMAGE, SDL_image, [:],
92 [SDLIMAGE_LIBS="${SDLIMAGE_LIBS} -lSDL_image"])
93save_CPPFLAGS="${CPPFLAGS}"
94SDL_CFLAGS="${SDL_CFLAGS} ${SDLMIXER_CFLAGS} ${SDLIMAGE_CFLAGS}"
95SDL_LIBS="${SDL_LIBS} ${SDLMIXER_LIBS} ${SDLIMAGE_LIBS}"
96
97CPPFLAGS="${CPPFLAGS} ${SDL_CFLAGS}"
98AC_CHECK_HEADERS(SDL_mixer.h, [:], [ac_cv_my_have_sdl="no"])
99AC_CHECK_HEADERS(SDL_image.h, [:], [ac_cv_my_have_sdl="no"])
100CPPFLAGS="${save_CPPFLAGS}"
101if test "${ac_cv_my_have_sdl}" = "no"; then
102  AC_MSG_ERROR([[One of SDL, SDL_Image or SDL_Mixer not found]])
103else
104  AC_DEFINE(USE_SDL, 1, Define to 1 to use SDL_image)
105fi
106AM_CONDITIONAL(USE_SDL, test "${ac_cv_my_have_sdl}" = "yes")
107
108
109dnl Use libcaca? (required for font generation)
110ac_cv_my_have_caca="no"
111PKG_CHECK_MODULES(CACA, caca >= 0.99.beta17, [ac_cv_my_have_caca="yes"], [:])
112if test "${ac_cv_my_have_caca}" != "no"; then
113  AC_DEFINE(USE_CACA, 1, Define to 1 to use libcaca)
114fi
115AM_CONDITIONAL(USE_CACA, test "${ac_cv_my_have_caca}" != "no")
116
117
118dnl Use libpipi? (required for video recording)
119ac_cv_my_have_pipi="no"
120PKG_CHECK_MODULES(PIPI, pipi, [ac_cv_my_have_pipi="yes"], [:])
121if test "${ac_cv_my_have_pipi}" != "no"; then
122  AC_DEFINE(USE_PIPI, 1, Define to 1 to use libpipi)
123fi
124AM_CONDITIONAL(USE_PIPI, test "${ac_cv_my_have_pipi}" != "no")
125
126
127dnl Use GTK+? (required for the deushax editor)
128ac_cv_my_have_gtkgl="no"
129PKG_CHECK_MODULES(GTK, gtk+-2.0, [ac_cv_my_have_gtkgl="yes"], [:])
130PKG_CHECK_MODULES(GTKGL, gtkgl-2.0, [:], [ac_cv_my_have_gtkgl="no"])
131if test "${ac_cv_my_have_gtkgl}" != "no"; then
132  AC_DEFINE(USE_GTKGL, 1, Define to 1 to use GtkGl)
133fi
134AM_CONDITIONAL(USE_GTKGL, test "${ac_cv_my_have_gtkgl}" != "no")
135
136
137dnl Use cppunit for unit tests?
138PKG_CHECK_MODULES(CPPUNIT, cppunit, [CPPUNIT="yes"], [CPPUNIT="no"])
139AM_CONDITIONAL(USE_CPPUNIT, test "$CPPUNIT" = "yes")
140
141
142# How to use the Lol Engine inside this tree
143LOL_CFLAGS="$LOL_CFLAGS -I \$(top_srcdir)/src $SDL_CFLAGS"
144LOL_LIBS="$LOL_LIBS $SDL_LIBS"
145
146AC_SUBST(MATH_LIBS)
147AC_SUBST(LOL_CFLAGS)
148AC_SUBST(LOL_LIBS)
149
150AC_CONFIG_FILES([
151  Makefile
152  src/Makefile
153  test/Makefile
154  monsterz/Makefile
155  deushax/Makefile
156  tools/Makefile
157  art/Makefile
158  art/test/Makefile
159  gfx/Makefile
160  gfx/font/Makefile
161  maps/Makefile
162])
163
164AC_OUTPUT
165
Note: See TracBrowser for help on using the repository browser.