source: trunk/orbital/gun-scanner.l @ 1519 Tweet

%{
//
// Orbital
//
// Copyright: (c) 2009-2012 Cédric Lecacheur <jordx@free.fr>
//            (c) 2009-2012 Benjamin Huet <huet.benjamin@gmail.com>
//            (c) 2012 Sam Hocevar <sam@hocevar.net>
//

#if defined HAVE_CONFIG_H
#   include "config.h"
#endif

#include <cstdlib>
using std::exit;
using std::malloc;
using std::realloc;
using std::free;

#include "core.h"
#include "loldebug.h"

using namespace lol;

#include "../gun-compiler.h"

typedef orbital::GunParser::token token;
typedef orbital::GunParser::token_type token_type;

#ifndef YY_DECL
#   define YY_DECL orbital::GunParser::token_type \
        orbital::GunScanner::lex(orbital::GunParser::semantic_type* yylval, \
                                 orbital::GunParser::location_type* yylloc)
#endif

#define yyterminate() return token::T_END
#define YY_NO_UNISTD_H
#define YY_USER_ACTION yylloc->columns(yyleng);
%}

%option c++ prefix="Gun"
%option batch yywrap nounput stack

%%

%{
    /* reset location at the beginning of yylex() */
    yylloc->step();
%}

ai    { return token::T_AI; }
pai   { return token::T_PAI; }
ca    { return token::T_CA; }
sa    { return token::T_SA; }
tim   { return token::T_TIM; }
so    { return token::T_SO; }
rd    { return token::T_RD; }
spd   { return token::T_SPD; }
moda  { return token::T_MODA; }
modb  { return token::T_MODB; }
ffb   { return token::T_FFB; }
ffp   { return token::T_FFP; }
fb    { return token::T_FB; }
fp    { return token::T_FP; }
sk    { return token::T_SK; }
loop  { return token::T_LOOP; }

[-+]?[0-9]*\.?[0-9]+([eE][-+]?[0-9]+)? {
        yylval->fval = std::atof(yytext); return token::NUMBER; }
-     { return token_type('-'); }
,     { return token_type(','); }
[.\n] { /* ignore everything else */ }

%%

orbital::GunScanner::GunScanner(char const *command)
    : GunFlexLexer(0, 0),
      m_input(command)
{
}

orbital::GunScanner::~GunScanner()
{
}

int orbital::GunScanner::LexerInput(char* buf, int max_size)
{
    buf[0] = m_input[0];
    if (buf[0])
        ++m_input;
    return buf[0] ? 1 : 0;
}

#ifdef yylex
#undef yylex
#endif
int GunFlexLexer::yylex()
{
    std::cerr << "in GunFlexLexer::yylex() !" << std::endl;
    return 0;
}

int GunFlexLexer::yywrap()
{
    return 1;
}