source: trunk/src/easymesh/easymesh-parser.y @ 2152

Last change on this file since 2152 was 2152, checked in by sam, 7 years ago

easymesh: motherfucking planetary gears demo.

File size: 6.2 KB
Line 
1%{
2//
3// Lol Engine
4//
5// Copyright: (c) 2010-2012 Sam Hocevar <sam@hocevar.net>
6//            (c) 2009-2012 Cédric Lecacheur <jordx@free.fr>
7//            (c) 2009-2012 Benjamin Huet <huet.benjamin@gmail.com>
8//   This program is free software; you can redistribute it and/or
9//   modify it under the terms of the Do What The Fuck You Want To
10//   Public License, Version 2, as published by Sam Hocevar. See
11//   http://sam.zoy.org/projects/COPYING.WTFPL for more details.
12//
13
14#if defined HAVE_CONFIG_H
15#   include "config.h"
16#endif
17
18#include "core.h"
19#include "easymesh/easymesh.h"
20
21#include <string>
22
23%}
24
25%require "2.3"
26%debug
27%defines
28%skeleton "lalr1.cc"
29%name-prefix="lol"
30%define parser_class_name "EasyMeshParser"
31%locations
32%parse-param { class EasyMeshCompiler& mc }
33%error-verbose
34
35%union
36{
37    float fval;
38    /* Can't use uin32_t here for some reason */
39    unsigned u32val;
40    struct { float f0, f1, f2, f3, f4, f5, f6, f7, f8, f9; } args;
41}
42
43%start mesh_description
44
45%token T_COLOR T_BGCOLOR
46
47%token T_TRANSLATEX T_ROTATEX T_TAPERX T_SCALEX T_MIRRORX
48%token T_TRANSLATEY T_ROTATEY T_TAPERY T_SCALEY T_MIRRORY
49%token T_TRANSLATEZ T_ROTATEZ T_TAPERZ T_SCALEZ T_MIRRORZ
50%token T_TRANSLATE T_SCALE T_TOGGLESCALEWINDING
51%token T_CHAMFER
52
53%token T_CYLINDER T_BOX T_SMOOTHCHAMFBOX T_FLATCHAMFBOX T_SPHERE T_CAPSULE
54%token T_STAR T_EXPANDEDSTAR T_DISC T_TRIANGLE T_QUAD T_COG T_TORUS
55
56%token T_END 0
57%token T_ERROR
58
59%token <fval> NUMBER
60%token <u32val> COLOR
61
62%type <fval> number
63%type <args> args1 args2 args3 args4 args5 args6 args7 args8 args9 args10
64
65%{
66#include "easymesh/easymesh-compiler.h"
67
68#undef yylex
69#define yylex mc.m_lexer->lex
70%}
71
72%%
73
74mesh_description:
75    mesh_expression_list T_END
76    ;
77
78mesh_expression_list:
79    mesh_expression
80  | mesh_expression mesh_expression_list
81  ;
82
83mesh_expression:
84    mesh_command_list
85  | mesh_open mesh_expression_list mesh_close
86    ;
87
88mesh_open:
89    '['       { mc.m_mesh.OpenBrace(); }
90    ;
91
92mesh_close:
93    ']'       { mc.m_mesh.CloseBrace(); }
94    ;
95
96mesh_command_list:
97    mesh_command
98  | mesh_command_list mesh_command
99    ;
100
101mesh_command:
102    color_command
103  | transform_command
104  | primitive_command
105    ;
106
107color_command:
108    T_COLOR args4   { mc.m_mesh.SetCurColor(vec4($2.f0, $2.f1, $2.f2, $2.f3)); }
109  | T_COLOR COLOR   { uint32_t x = $2;
110                      vec4 v(x >> 24, (x >> 16) & 0xff, (x >> 8) & 0xff, x & 0xff);
111                      mc.m_mesh.SetCurColor(vec4(v) * (1. / 255)); }
112  | T_BGCOLOR args4 { mc.m_mesh.SetCurColor2(vec4($2.f0, $2.f1, $2.f2, $2.f3)); }
113  | T_BGCOLOR COLOR { uint32_t x = $2;
114                      vec4 v(x >> 24, (x >> 16) & 0xff, (x >> 8) & 0xff, x & 0xff);
115                      mc.m_mesh.SetCurColor2(vec4(v) * (1. / 255)); }
116    ;
117
118transform_command:
119    T_CHAMFER args1     { mc.m_mesh.Chamfer($2.f0); }
120  | T_TRANSLATEX args1  { mc.m_mesh.Translate(vec3($2.f0, 0, 0)); }
121  | T_TRANSLATEY args1  { mc.m_mesh.Translate(vec3(0, $2.f0, 0)); }
122  | T_TRANSLATEZ args1  { mc.m_mesh.Translate(vec3(0, 0, $2.f0)); }
123  | T_TRANSLATE args3   { mc.m_mesh.Translate(vec3($2.f0, $2.f1, $2.f2)); }
124  | T_ROTATEX args1     { mc.m_mesh.RotateX($2.f0); }
125  | T_ROTATEY args1     { mc.m_mesh.RotateY($2.f0); }
126  | T_ROTATEZ args1     { mc.m_mesh.RotateZ($2.f0); }
127  | T_TAPERX args3      { mc.m_mesh.TaperX($2.f0, $2.f1, $2.f2); }
128  | T_TAPERY args3      { mc.m_mesh.TaperY($2.f0, $2.f1, $2.f2); }
129  | T_TAPERZ args3      { mc.m_mesh.TaperZ($2.f0, $2.f1, $2.f2); }
130  | T_SCALEX args1      { mc.m_mesh.Scale(vec3($2.f0, 1.0, 1.0)); }
131  | T_SCALEY args1      { mc.m_mesh.Scale(vec3(1.0, $2.f0, 1.0)); }
132  | T_SCALEZ args1      { mc.m_mesh.Scale(vec3(1.0, 1.0, $2.f0)); }
133  | T_SCALE args3       { mc.m_mesh.Scale(vec3($2.f0, $2.f1, $2.f2)); }
134  | T_MIRRORX           { mc.m_mesh.MirrorX(); }
135  | T_MIRRORY           { mc.m_mesh.MirrorY(); }
136  | T_MIRRORZ           { mc.m_mesh.MirrorZ(); }
137  | T_TOGGLESCALEWINDING { mc.m_mesh.ToggleScaleWinding(); }
138    ;
139
140primitive_command:
141    T_CYLINDER args6       { mc.m_mesh.AppendCylinder((int)$2.f0, $2.f1,
142                                                 $2.f2, $2.f3,
143                                                 (int)$2.f4, (int)$2.f5); }
144  | T_BOX args3            { mc.m_mesh.AppendBox(vec3($2.f0, $2.f1, $2.f2)); }
145  | T_SMOOTHCHAMFBOX args4 { mc.m_mesh.AppendSmoothChamfBox(vec3($2.f0, $2.f1,
146                                                            $2.f2), $2.f3); }
147  | T_FLATCHAMFBOX args4   { mc.m_mesh.AppendFlatChamfBox(vec3($2.f0, $2.f1,
148                                                          $2.f2), $2.f3); }
149  | T_SPHERE args4         { mc.m_mesh.AppendSphere($2.f0,
150                                               vec3($2.f1, $2.f2, $2.f3)); }
151  | T_CAPSULE args3        { mc.m_mesh.AppendCapsule($2.f0, $2.f1, $2.f2); }
152  | T_TORUS args3          { mc.m_mesh.AppendTorus((int)$2.f0, $2.f1, $2.f2); }
153  | T_STAR args5           { mc.m_mesh.AppendStar((int)$2.f0, $2.f1, $2.f2,
154                                             (int)$2.f3, (int)$2.f4); }
155  | T_EXPANDEDSTAR args4   { mc.m_mesh.AppendExpandedStar((int)$2.f0, $2.f1,
156                                                     $2.f2, $2.f3); }
157  | T_DISC args3           { mc.m_mesh.AppendDisc((int)$2.f0, $2.f1, (int)$2.f2); }
158  | T_TRIANGLE args2       { mc.m_mesh.AppendSimpleTriangle($2.f0, (int)$2.f1); }
159  | T_QUAD args2           { mc.m_mesh.AppendSimpleQuad($2.f0, (int)$2.f1); }
160  | T_COG args10           { mc.m_mesh.AppendCog((int)$2.f0, $2.f1,
161                                 $2.f2, $2.f3, $2.f4, $2.f5, $2.f6,
162                                 $2.f7, $2.f8, (int)$2.f9); }
163    ;
164
165args1: number { $$.f0 = $1; } ;
166args2: args1 number { $$ = $1; $$.f1 = $2; } ;
167args3: args2 number { $$ = $1; $$.f2 = $2; } ;
168args4: args3 number { $$ = $1; $$.f3 = $2; } ;
169args5: args4 number { $$ = $1; $$.f4 = $2; } ;
170args6: args5 number { $$ = $1; $$.f5 = $2; } ;
171args7: args6 number { $$ = $1; $$.f6 = $2; } ;
172args8: args7 number { $$ = $1; $$.f7 = $2; } ;
173args9: args8 number { $$ = $1; $$.f8 = $2; } ;
174args10: args9 number { $$ = $1; $$.f9 = $2; } ;
175
176number:
177    NUMBER       { $$ = $1; }
178  | '-' number   { $$ = -$2; }
179    ;
180
181%%
182
183void lol::EasyMeshParser::error(const EasyMeshParser::location_type& l,
184                                const std::string& m)
185{
186    mc.Error(l, m);
187}
188
Note: See TracBrowser for help on using the repository browser.