source: trunk/src/easymesh/easymesh-parser.y @ 2226

Last change on this file since 2226 was 2226, checked in by touky, 7 years ago

Added CSG v0.001a : not optimized, too much operation makes it slow. triangle count is not optimized.
Useage : "...[.... csg*]" equals "current mesh -CSG- the mesh in the braces".
Keywords : CsgUnion<csgu>, CsgSubstract<csgs>, CsgAnd<csga>, CsgXor<csgx>
TODO : cleanup useless code.
TODO : Some bugs are still present, some face that disappear should not.
TODO : Correct epsilon useage (see geometry files).
TODO : Coplanar face are not handled -at all-.
TODO : Vertex count goes through the roof in case of a Xor.

File size: 6.5 KB
Line 
1%{
2//
3// Lol Engine
4//
5// Copyright: (c) 2010-2013 Sam Hocevar <sam@hocevar.net>
6//            (c) 2009-2013 Cédric Lecacheur <jordx@free.fr>
7//            (c) 2009-2013 Benjamin "Touky" Huet <huet.benjamin@gmail.com>
8//   This program is free software; you can redistribute it and/or
9//   modify it under the terms of the Do What The Fuck You Want To
10//   Public License, Version 2, as published by Sam Hocevar. See
11//   http://www.wtfpl.net/ for more details.
12//
13
14#if defined HAVE_CONFIG_H
15#   include "config.h"
16#endif
17
18#include "core.h"
19#include "easymesh/easymesh.h"
20
21#include <string>
22
23%}
24
25%require "2.3"
26%debug
27%defines
28%skeleton "lalr1.cc"
29%name-prefix="lol"
30%define parser_class_name "EasyMeshParser"
31%locations
32%parse-param { class EasyMeshCompiler& mc }
33%error-verbose
34
35%union
36{
37    float fval;
38    /* Can't use uin32_t here for some reason */
39    unsigned u32val;
40    struct { float f0, f1, f2, f3, f4, f5, f6, f7, f8, f9; } args;
41}
42
43%start mesh_description
44
45%token T_COLOR T_BGCOLOR
46
47%token T_TRANSLATEX T_ROTATEX T_TAPERX T_SCALEX T_MIRRORX
48%token T_TRANSLATEY T_ROTATEY T_TAPERY T_SCALEY T_MIRRORY
49%token T_TRANSLATEZ T_ROTATEZ T_TAPERZ T_SCALEZ T_MIRRORZ
50%token T_TRANSLATE T_SCALE T_TOGGLESCALEWINDING
51%token T_CSGUNION T_CSGSUBSTRACT T_CSGAND T_CSGXOR
52%token T_CHAMFER
53
54%token T_CYLINDER T_BOX T_SMOOTHCHAMFBOX T_FLATCHAMFBOX T_SPHERE T_CAPSULE
55%token T_STAR T_EXPANDEDSTAR T_DISC T_TRIANGLE T_QUAD T_COG T_TORUS
56
57%token T_END 0
58%token T_ERROR
59
60%token <fval> NUMBER
61%token <u32val> COLOR
62
63%type <fval> number
64%type <args> args1 args2 args3 args4 args5 args6 args7 args8 args9 args10
65
66%{
67#include "easymesh/easymesh-compiler.h"
68
69#undef yylex
70#define yylex mc.m_lexer->lex
71%}
72
73%%
74
75mesh_description:
76    mesh_expression_list T_END
77    ;
78
79mesh_expression_list:
80    mesh_expression
81  | mesh_expression mesh_expression_list
82  ;
83
84mesh_expression:
85    mesh_command_list
86  | mesh_open mesh_expression_list mesh_close
87    ;
88
89mesh_open:
90    '['       { mc.m_mesh.OpenBrace(); }
91    ;
92
93mesh_close:
94    ']'       { mc.m_mesh.CloseBrace(); }
95    ;
96
97mesh_command_list:
98    mesh_command
99  | mesh_command_list mesh_command
100    ;
101
102mesh_command:
103    color_command
104  | transform_command
105  | primitive_command
106    ;
107
108color_command:
109    T_COLOR args4   { mc.m_mesh.SetCurColor(vec4($2.f0, $2.f1, $2.f2, $2.f3)); }
110  | T_COLOR COLOR   { uint32_t x = $2;
111                      vec4 v(x >> 24, (x >> 16) & 0xff, (x >> 8) & 0xff, x & 0xff);
112                      mc.m_mesh.SetCurColor(vec4(v) * (1. / 255)); }
113  | T_BGCOLOR args4 { mc.m_mesh.SetCurColor2(vec4($2.f0, $2.f1, $2.f2, $2.f3)); }
114  | T_BGCOLOR COLOR { uint32_t x = $2;
115                      vec4 v(x >> 24, (x >> 16) & 0xff, (x >> 8) & 0xff, x & 0xff);
116                      mc.m_mesh.SetCurColor2(vec4(v) * (1. / 255)); }
117    ;
118
119transform_command:
120    T_CHAMFER args1        { mc.m_mesh.Chamfer($2.f0); }
121  | T_TRANSLATEX args1     { mc.m_mesh.Translate(vec3($2.f0, 0, 0)); }
122  | T_TRANSLATEY args1     { mc.m_mesh.Translate(vec3(0, $2.f0, 0)); }
123  | T_TRANSLATEZ args1     { mc.m_mesh.Translate(vec3(0, 0, $2.f0)); }
124  | T_TRANSLATE args3      { mc.m_mesh.Translate(vec3($2.f0, $2.f1, $2.f2)); }
125  | T_ROTATEX args1        { mc.m_mesh.RotateX($2.f0); }
126  | T_ROTATEY args1        { mc.m_mesh.RotateY($2.f0); }
127  | T_ROTATEZ args1        { mc.m_mesh.RotateZ($2.f0); }
128  | T_TAPERX args3         { mc.m_mesh.TaperX($2.f0, $2.f1, $2.f2); }
129  | T_TAPERY args3         { mc.m_mesh.TaperY($2.f0, $2.f1, $2.f2); }
130  | T_TAPERZ args3         { mc.m_mesh.TaperZ($2.f0, $2.f1, $2.f2); }
131  | T_SCALEX args1         { mc.m_mesh.Scale(vec3($2.f0, 1.0, 1.0)); }
132  | T_SCALEY args1         { mc.m_mesh.Scale(vec3(1.0, $2.f0, 1.0)); }
133  | T_SCALEZ args1         { mc.m_mesh.Scale(vec3(1.0, 1.0, $2.f0)); }
134  | T_SCALE args3          { mc.m_mesh.Scale(vec3($2.f0, $2.f1, $2.f2)); }
135  | T_MIRRORX              { mc.m_mesh.MirrorX(); }
136  | T_MIRRORY              { mc.m_mesh.MirrorY(); }
137  | T_MIRRORZ              { mc.m_mesh.MirrorZ(); }
138  | T_TOGGLESCALEWINDING   { mc.m_mesh.ToggleScaleWinding(); }
139  | T_CSGUNION             { mc.m_mesh.CsgUnion(); }
140  | T_CSGSUBSTRACT         { mc.m_mesh.CsgSubstract(); }
141  | T_CSGAND               { mc.m_mesh.CsgAnd(); }
142  | T_CSGXOR               { mc.m_mesh.CsgXor(); }
143    ;
144
145primitive_command:
146    T_CYLINDER args6       { mc.m_mesh.AppendCylinder((int)$2.f0, $2.f1,
147                                                 $2.f2, $2.f3,
148                                                 (int)$2.f4, (int)$2.f5); }
149  | T_BOX args3            { mc.m_mesh.AppendBox(vec3($2.f0, $2.f1, $2.f2)); }
150  | T_SMOOTHCHAMFBOX args4 { mc.m_mesh.AppendSmoothChamfBox(vec3($2.f0, $2.f1,
151                                                            $2.f2), $2.f3); }
152  | T_FLATCHAMFBOX args4   { mc.m_mesh.AppendFlatChamfBox(vec3($2.f0, $2.f1,
153                                                          $2.f2), $2.f3); }
154  | T_SPHERE args4         { mc.m_mesh.AppendSphere($2.f0,
155                                               vec3($2.f1, $2.f2, $2.f3)); }
156  | T_CAPSULE args3        { mc.m_mesh.AppendCapsule($2.f0, $2.f1, $2.f2); }
157  | T_TORUS args3          { mc.m_mesh.AppendTorus((int)$2.f0, $2.f1, $2.f2); }
158  | T_STAR args5           { mc.m_mesh.AppendStar((int)$2.f0, $2.f1, $2.f2,
159                                             (int)$2.f3, (int)$2.f4); }
160  | T_EXPANDEDSTAR args4   { mc.m_mesh.AppendExpandedStar((int)$2.f0, $2.f1,
161                                                     $2.f2, $2.f3); }
162  | T_DISC args3           { mc.m_mesh.AppendDisc((int)$2.f0, $2.f1, (int)$2.f2); }
163  | T_TRIANGLE args2       { mc.m_mesh.AppendSimpleTriangle($2.f0, (int)$2.f1); }
164  | T_QUAD args2           { mc.m_mesh.AppendSimpleQuad($2.f0, (int)$2.f1); }
165  | T_COG args10           { mc.m_mesh.AppendCog((int)$2.f0, $2.f1,
166                                 $2.f2, $2.f3, $2.f4, $2.f5, $2.f6,
167                                 $2.f7, $2.f8, (int)$2.f9); }
168    ;
169
170args1: number { $$.f0 = $1; } ;
171args2: args1 number { $$ = $1; $$.f1 = $2; } ;
172args3: args2 number { $$ = $1; $$.f2 = $2; } ;
173args4: args3 number { $$ = $1; $$.f3 = $2; } ;
174args5: args4 number { $$ = $1; $$.f4 = $2; } ;
175args6: args5 number { $$ = $1; $$.f5 = $2; } ;
176args7: args6 number { $$ = $1; $$.f6 = $2; } ;
177args8: args7 number { $$ = $1; $$.f7 = $2; } ;
178args9: args8 number { $$ = $1; $$.f8 = $2; } ;
179args10: args9 number { $$ = $1; $$.f9 = $2; } ;
180
181number:
182    NUMBER       { $$ = $1; }
183  | '-' number   { $$ = -$2; }
184    ;
185
186%%
187
188void lol::EasyMeshParser::error(const EasyMeshParser::location_type& l,
189                                const std::string& m)
190{
191    mc.Error(l, m);
192}
193
Note: See TracBrowser for help on using the repository browser.