source: trunk/tools/neercs/video/postfx.lolfx @ 2049

Last change on this file since 2049 was 2049, checked in by rez, 8 years ago

neercs: added theme support + 2 new themes [F4/F5 to switch]

File size: 3.4 KB
Line 
1[vert.glsl]
2
3#version 120
4
5void main()
6{
7    gl_Position=gl_Vertex;
8    gl_TexCoord[0]=gl_MultiTexCoord0;
9}
10
11[frag.glsl]
12
13#version 120
14
15uniform sampler2D texture;
16uniform vec2 screen_size;
17uniform vec2 ratio_2d;
18uniform float time;
19uniform vec2 deform;
20uniform vec4 ghost1;
21uniform vec4 ghost2;
22uniform vec4 glass;
23uniform vec3 gradient;
24uniform vec3 gradient_color;
25uniform float vignetting;
26uniform float aberration;
27uniform vec4 moire_h;
28uniform vec4 moire_v;
29uniform vec4 scanline_h;
30uniform vec4 scanline_v;
31uniform vec3 corner;
32uniform float sync;
33uniform float beat;
34
35vec2 screen(in vec2 p,in float bend,in float radius)
36{
37    float d=bend+sync*0.0625+beat*0.0375;
38    return p*(1.5-(radius*cos(p.x*d)+radius*cos(p.y*d)))-0.5;
39}
40
41vec3 get_color(in sampler2D tex,in vec2 p)
42{
43    return texture2D(tex,clamp(p,-1.0,0.0)).xyz;
44}
45
46float letterbox(in vec2 p,in float w,in float radius,in float smooth)
47{
48    return 1.0-smoothstep(smooth,1.0,length(max(abs(p*w+w/2.0)-vec2(radius),0.0))+radius);
49}
50
51void main(void)
52{
53    vec2 q=gl_FragCoord.xy/screen_size.xy;
54    vec2 p=-1.0+2.0*gl_FragCoord.xy/screen_size.xy;
55    p.y+=0.025*sync;
56    vec2 z=screen(p,deform.x,deform.y);
57    vec2 z1=screen(p,deform.x,deform.y+ghost1.z);
58    vec2 z2=screen(p,deform.x,deform.y+ghost2.z);
59    vec2 z3=screen(p,glass.w,deform.y+glass.x-glass.y);
60    vec2 z4=screen(p,glass.w,deform.y+glass.x+glass.y);
61    float mask=q.x*(6.0-q.x*6.0)*q.y*(6.0-q.y*6.0);
62
63    vec3 source=get_color(texture,z);
64    vec3 g1=get_color(texture,z1-ghost1.xy);
65    vec3 g2=get_color(texture,z2-ghost2.xy);
66    vec3 g3=get_color(texture,z3);
67    vec3 g4=get_color(texture,z4);
68
69    vec3 c=source+g1*ghost1.w+g2*ghost2.w;                   // mix
70
71    float v=aberration/float(screen_size.x/ratio_2d.x);      //+aberration/float(screen_size.x)*(2.0-mask);
72    vec3 ca1=get_color(texture,vec2(z.x-v,z.y));
73    vec3 ca2=get_color(texture,vec2(z.x+v,z.y));
74    c+=vec3(ca1.x,c.y,ca2.z);                                // chromatic aberration
75
76    vec3 c1=vec3(gradient_color.x,gradient_color.y,gradient_color.z);
77    vec3 c2=vec3(gradient_color.x,gradient_color.y,gradient_color.z)/4;
78    vec3 c3=vec3(1.0,1.0,1.0);
79    vec3 c4=vec3(gradient_color.z,gradient_color.y,gradient_color.x);
80    vec3 c5=vec3(gradient_color.z,gradient_color.y,gradient_color.x)/4;
81    vec3 r;
82    float r_p=gradient.x;
83    float r_h=gradient.y;
84    float r_h2=gradient.y/2;
85    float k=z.y+1.0;
86
87    if(k<=r_p-r_h2) r=mix(c1,c2,k*(1/(r_p-r_h2)));
88    if(k>r_p-r_h2&&k<=r_p) r=mix(c2,c3,(k-(r_p-r_h2))*(1/r_h2));
89    if(k>r_p&&k<r_p+r_h) r=mix(c3,c4,(k-r_p)*(1/r_h));
90    if(k>=r_p+r_h) r=mix(c4,c5,k*((k-(r_p+r_h))/(r_p-r_h)));
91
92    c*=moire_h.x+moire_h.y*sin(z.y*float(screen_size.y*moire_h.z)/ratio_2d.y)*sin(0.5+z.x*float(screen_size.x*moire_h.w)/ratio_2d.x); // moire h
93    c*=moire_v.x+moire_v.y*sin(z.x*float(screen_size.x*moire_v.z)/ratio_2d.x)*sin(0.5+z.y*float(screen_size.y*moire_v.w)/ratio_2d.y); // moire v
94    c*=scanline_h.x+scanline_h.y*cos(z.y*float(screen_size.y*scanline_h.z+scanline_h.w)/ratio_2d.y); // scanline h
95    c*=scanline_v.x+scanline_v.y*cos(z.x*float(screen_size.x*scanline_v.z+scanline_v.w)/ratio_2d.x); // scanline v
96    c+=r*gradient.z;                                         // gradient
97    c*=mix(1.0,mask,vignetting);                             // vignetting
98    c*=letterbox(z,corner.x+2.0,corner.y,corner.z);          // corner
99    c+=(g3+g4)*glass.z;                                      // glass
100    gl_FragColor=vec4(c,1.0);
101}
Note: See TracBrowser for help on using the repository browser.